saveInstCount.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
###############################################################################
# Copyright (c) 2010-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @userware
#       Save Design Statistics
#   @section
#       Create Reports
#   @description
#       Save the design statistic (as displayed in the `Tools->Report InstCount`
#       dialog) to a file.
#   @files
#       saveInstCount.tcl
#   @example
#       demo/rtl/aquarius/aquarius.f
#   @cmdline
#       -F @example[0]
#       -userware @files[0]
#   @tag
#       zdb report
###############################################################################


# -----------------------------------------------------------------------------
# saveInstCount - Save the design statistic (as displayed in the
#                 Tools->Report InstCount dialog) to a file.
# -----------------------------------------------------------------------------
#
proc saveInstCount {} {
    set db [gui database get]

    ##
    # Return if the database is empty.
    #
    if {$db == {}} {
        return
    }

    set file [gui window fileDialog saveFile "Save Report Inst Count" \
                                      {{"Text Files" .txt}}]
    if {$file == ""} {
        return
    }

    ##
    # Get the name of the top module.
    #
    set top ""
    $db foreach top top break

    ##
    # fill the array 'reportTab' with the design statistics.
    #
    array set reportTab {}
    $db report instCount reportTab $top

    ##
    # Convert result (from reportTab) into two sorted lists priList and modList.
    #
    set priList {}
    set modList {}
    set priSum 0
    set modSum 0
    foreach {nm cnt} [array get reportTab] {
        if {[string index $nm 0] == "P"} {
            lappend priList [list [string range $nm 1 end] $cnt]
            incr priSum $cnt
        } else {
            lappend modList [list [string range $nm 1 end] $cnt]
            incr modSum $cnt
        }
    }
    set modList [lsort -integer -decreasing -index 1 $modList]
    set priList [lsort -integer -decreasing -index 1 $priList]

    ##
    # Calculate the width of the first column.
    #
    set cwid 0
    if {($priSum + $modSum) > 0} {
        set cwid [expr {int(log($priSum + $modSum) / log(10) + 1.0)}]
    }

    ##
    # Open the file for writing and dump the report.
    #
    set o [open $file "w"]
    foreach {label resList} [list \
                [format "%${cwid}d  %s" $modSum Modules]    $modList \
                [format "%${cwid}d  %s" $priSum Primitives] $priList] {
        puts $o $label
        foreach obj $resList {
            puts $o [format "%${cwid}d  %s" [lindex $obj 1] [lindex $obj 0]]
        }
    }
    close $o
}


# =============================================================================
# Extend the main menu and add a "Save Inst Count" entry.
# =============================================================================
#
gui menu command {"Userware" "Save Inst Count"} {saveInstCount}