guiCustomization/customizePopup.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
###############################################################################
# Copyright (c) 2017-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @userware
#       Custom Popup
#   @section
#       GUI Specific Userware Examples
#   @description
#       Example code for doc/tutorial/guiCustomization.html
#   @files
#       guiCustomization/customizePopup.tcl
#   @example
#       ""
#   @cmdline
#       -userware @files[0]
#   @tag
#       gui
###############################################################################


# =============================================================================
# CreatePopup - Create the custom Popup menu entries.
# =============================================================================
#
proc CustomizePopup:CreatePopup {} {
    gui popup append       \
        -menuname "Custom" \
        "Toggle Net Names" \
        {CustomizePopup:toggleNetNames}
    gui popup append       \
        -menuname "Custom" \
        "Rotate +90"       \
        {CustomizePopup:rotate +R90}

    gui popup customize {CustomizePopup:customize}
}


# -----------------------------------------------------------------------------
# toggleNetNames - Toggle the display of net names.
# -----------------------------------------------------------------------------
#
proc CustomizePopup:toggleNetNames {oids} {
    gui settings set "nlv:shownetname" \
        [expr {![gui settings get "nlv:shownetname"]}]
    gui settings changed
}


# -----------------------------------------------------------------------------
# rotate - Set the rotation mode of all instances in $oids to $mode.
# -----------------------------------------------------------------------------
#
proc CustomizePopup:rotate {mode oids} {
    set db [gui database get]
    foreach oid $oids {
        if {[$db oid type $oid] eq "inst"} {
            $db orient $oid $mode
        }
    }
    gui database modified
}


# -----------------------------------------------------------------------------
# containsInst - Return 1 if $oids contains at least one instance OID.
# -----------------------------------------------------------------------------
#
proc CustomizePopup:containsInst {oids} {
    set db [gui database get]
    if {$db != {}} {
        foreach oid $oids {
            if {[$db oid type $oid] eq "inst"} {
                return 1
            }
        }
    }
    return 0
}


# -----------------------------------------------------------------------------
# customize - Enable the custom popup menu entries depending on the current
#             selection.
# -----------------------------------------------------------------------------
#
proc CustomizePopup:customize {menu oids} {
    ##
    # Always enable our own "Custom" popup menu item.
    #
    $menu entryconfigure "Custom" -state normal

    ##
    # Get the "Custom" sub-menu.
    #
    set customMenu [$menu entrycget "Custom" -menu]

    ##
    # Always enable "Custom / Toggle Net Names".
    #
    $customMenu entryconfigure "Toggle Net Names" \
        -state normal

    ##
    # Only enable "Custom / Rotate +90" if at least one instance is selected.
    #
    set hasInst [CustomizePopup:containsInst $oids]
    $customMenu entryconfigure "Rotate +90" \
        -state [expr {$hasInst ? "normal" : "disabled"}]
}


##
# Call the main procedure to create the custom Popup menu entries.
#
CustomizePopup:CreatePopup