floatingOutputs.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
###############################################################################
# Copyright (c) 2010-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Find Floating Outputs
#   @namespace
#       FloatingOutputs
#   @section
#       Analyze the Loaded Database
#   @description
#       Loop over all signals report signals that do not drive anything.
#   @non-interactive
#   @files
#       floatingOutputs.tcl
#   @example
#       demo/spice/amd2901.sp
#   @cmdline
#       -hspice @example[0]
#       -userware @files[0]
#   @tag
#       spice netlist
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc FloatingOutputs:Init {} {
    gui database runOrRegisterChangedCallback FloatingOutputs:Run
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc FloatingOutputs:Finit {} {
    gui database removeChangedCallback FloatingOutputs:Run
}


# =============================================================================
# Run - Loop over all signals report signals that do not
#       drive anything.
# =============================================================================
#
proc FloatingOutputs:Run {db} {
    ##
    # Return if the database is empty.
    #
    if {$db == {}} {
        return
    }

    ##
    # result List
    #
    set resList {}

    ##
    # normally there should be only one top module
    #
    $db foreach top top {
        $db flat foreach signal $top sig {
            ##
            # skip power, ground and negpower nets
            #
            if {[$db isPgNet $sig]} {
                continue
            }

            set driverCnt 0
            set bidirCnt  0
            set inputCnt  0

            $db flat foreach pin $sig pin {
                if {[$db oid type $pin] == "port"} {
                    set driver "input"  ;# input port is driver
                } else {
                    set driver "output" ;# output pin is driver
                }
                set dir [$db directionOf $pin]
                if {$dir == $driver} {
                    incr driverCnt
                } elseif {$dir == "inout"} {
                    incr bidirCnt
                } else {
                    incr inputCnt
                }
                if {$inputCnt} {
                    ##
                    # speedup: we have all we need
                    #
                    break
                }
                if {$bidirCnt > 2} {
                    ##
                    # speedup: we have all we need
                    #
                    break
                }
            }
            if {!$inputCnt} {
                if {($driverCnt && !$bidirCnt) ||
                    (!$driverCnt && $bidirCnt == 1)} {
                    lappend resList $sig
                }
            }
        }
    }

    ##
    # Clear and activate the Mem Window
    #
    gui mem clear
    gui window show Schem
    gui window show Mem

    ##
    # Store the result into the Mem Window.
    #
    gui mem append $resList
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
FloatingOutputs:Init