floatingNets.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
###############################################################################
# Copyright (c) 2020-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Find Floating Members in NetBuses
#   @namespace
#       FloatingNets
#   @section
#       Analyze the Loaded Database
#   @description
#       Loop over the database and find floating/dangling member nets in
#       netbuses. Results are displayed in the Mem window.
#   @non-interactive
#   @files
#       floatingNets.tcl
#   @example
#       demo/rtl/aquarius/aquarius.f
#   @cmdline
#       -F @example[0]
#       -userware @files[0]
#   @tag
#       rtl zdb
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc FloatingNets:Init {} {
    gui menu command \
        {"Userware" "Find Floating NetBus Members"} \
        [list FloatingNets:Run]
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc FloatingNets:Finit {} {
    gui menu removeEntry {"Userware" "Find Floating NetBus Members"}
}


# =============================================================================
# Run - Find all netBuses with floating nets.
# =============================================================================
#
proc FloatingNets:Run {} {
    set db [gui database get]

    ##
    # Stop if there is no db.
    #
    if {$db == {}} {
        return
    }

    ##
    # Show progress.
    #
    zprogress begin
    zprogress push "Searching for floating nets" 1.0

    ##
    # Init variables.
    #
    set floatingNets {}
    set moduleCount  [$db count module]
    set progress     0

    ##
    # Iterate over all modules of the design.
    #
    $db foreach module curModule {
        ##
        # Update zprogress.
        #
        if {[zprogress update "" [incr progress] $moduleCount]} {
            break
        }

        ##
        # Check each netBus of the current module.
        #
        $db foreach netBus $curModule curNetBus {
            ##
            # Check all members of the netBus.
            #
            $db foreach member $curNetBus curNet {
                ##
                # Ignore null members (which have 0 connections).
                #
                if {[$db oid isnull $curNet]} {
                    continue
                }

                ##
                # If the net has less than 2 connections,
                # then it is a floating net.
                #
                if {[$db count pin $curNet] < 2} {
                    lappend floatingNets $curNet
                }
            }
        }
    }

    ##
    # Clear and activate the Mem Window.
    #
    gui mem clear
    gui window show Mem
    gui window show Schem


    if {[llength $floatingNets] == 0} {
        lappend floatingNets "\"No floating members found.\""
    }

    ##
    # Display results in Mem Window.
    #
    gui mem append $floatingNets

    zprogress pop
    zprogress end
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
FloatingNets:Init