flagLeafCells.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
###############################################################################
# Copyright (c) 2020-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Flag Leaf Cells
#   @namespace
#       FlagLeafCells
#   @section
#       Modify the Loaded Database
#   @description
#       Flag all modules listed in the provided side file as a leaf cell.
#   @files
#       flagLeafCells.tcl
#   @example
#       demo/spice/gl85.sp
#       demo/api/flagLeafCells.txt
#   @cmdline
#       -hspice @example[0]
#       -userware2 @files[0] @example[1]
#   @tag
#       netlist verilog spice
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc FlagLeafCells:Init {argc argv} {
    global FlagLeafCells

    ##
    # Add menu entry.
    #
    gui menu command {"Userware" "Load FlagLeafCells Config"} \
        [list FlagLeafCells:Start true]

    ##
    # Get the name of the configuration file.
    #
    set FlagLeafCells(configFile) [lindex $argv 0]

    ##
    # Install callback and run it immediately if there already is a database.
    #
    gui database runAndRegisterChangedCallback [list FlagLeafCells:Start false]
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc FlagLeafCells:Finit {} {
    ##
    # Undo modifications of the GUI.
    #
    gui menu removeEntry {"Userware" "Load FlagLeafCells Config"}

    ##
    # Remove the database changed callback.
    #
    gui database removeChangedCallback FlagLeafCells:Start
}


# =============================================================================
# Start -
# =============================================================================
#
proc FlagLeafCells:Start {interactive {db {}}} {
    global FlagLeafCells

    ##
    # Get the database handle and return of no database is available.
    #
    if {$db == {}} {
        set db [gui database get]
        if {$db == {}} {
            return
        }
    }

    ##
    # If running interactively, then show a file open dialog to browse
    # for a configuration file.
    #
    if {$interactive} {
        set FlagLeafCells(configFile) [gui window fileDialog openFile \
            "Open a Config File" \
            {{"FlagLeafCells-Config" {".txt"}}}]
    }

    ##
    # Return from this procedure if no configuration file is set.
    #
    if {$FlagLeafCells(configFile) eq ""} {
        return
    }

    ##
    # Variable to remember if a leaf cell was flagged.
    #
    set leafCellFlagged false

    ##
    # Read the configuration file and store the values.
    #
    set in [open $FlagLeafCells(configFile) rb]
    while {![eof $in]} {
        gets $in line

        set name [string trim [lindex $line 0]]
        if {($name eq "") || [string match "#*" $name]} {
            continue
        }

        ##
        # Search a module with this name in the database.
        #
        set module [$db search module $name]

        ##
        # Check if a module could be found.
        #
        if {[$db oid isnull $module]} {
            continue
        }

        ##
        # Set the leafcell flag at the module.
        #
        $db flag $module set leafcell

        ##
        # Remember that at least one leafcell flag was set.
        #
        set leafCellFlagged true
    }
    close $in

    ##
    # Return if no module was flagged as a leaf cell.
    #
    if {!$leafCellFlagged} {
        return
    }

    ##
    # Set all flagged resistor modules as primitives.
    #
    $db setPrimitive -flag

    ##
    # Update the GUI.
    #
    gui database modified
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
FlagLeafCells:Init $argc $argv