erc/check02.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
###############################################################################
# Copyright (c) 2017-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @script
#       Detect floating gates at the MOS devices, either directly or through
#       pins of a resistor.
#
#       Algorithm
#           1. Identify all MOS devices in the design.
#           2. Check if the gate pin is either not connected at all or connects
#              to a floating node.
#           3. Add the devices that violate the above rule to the result list.
#
#       Example
#           demo/api/erc/testcase02.sp
###############################################################################


# =============================================================================
# Check02 -
# =============================================================================
#
proc ERC:Check02 {db} {
    ##
    # Initialize the result list.
    #
    set resList {}

    ##
    # Flag devices in the loaded database.
    #
    zprogress push "" 0.05
    ERC:FlagDevices $db {"NMOS" "PMOS"}
    if {[zprogress pop]} {
        return
    }

    zprogress push "" 0.1
    set count [$db count primitive]
    set i 0
    $db foreach primitive primitive {
        if {[zprogress update "" [incr i] $count]} {
            break
        }

        ##
        # Get the function of this primitive.
        #
        set func [$db primFuncOf $primitive]

        ##
        # If the function is in the given list of 'green' devices then set the
        # green flag at this device to identify them in the cone search.
        #
        if {($func eq "NMOS") || ($func eq "PMOS")} {
            set port [$db getFuncPort $primitive -name gate]
            $db flag $port set red
        }
    }
    if {[zprogress pop]} {
        return
    }

    ##
    # Loop over top modules.
    #
    zprogress push "" 1.0
    set count [$db report objCount -inst]
    set i 0
    $db foreach top top {
        ##
        # Loop over all flat instances in the loaded design.
        #
        $db flat foreach instOfCell green $top inst {
            zmessage print DBG "  Process instance [$db oid print $inst]"

            ##
            # Investigate only the gate pin for floating connections.
            #
            set gatePin [$db getFuncPort $inst -name gate]
            zmessage print DBG "    Process gate pin [$db oid print $gatePin]"

            ##
            # Use the 'cone' API to search for paths to either power or ground
            # nets, to toplevel ports and device except resistors (not
            # flagged with the red flag).
            #
            zprogress push "" [expr {double([incr i]) / $count}]
            set res [$db cone -in -targetPGNet \
                                  -targetIO \
                                  -targetFlaggedCell red \
                                  $gatePin]
            if {[zprogress pop]} {
                break
            }

            ##
            # If the result list is not empty then the gate pin is
            # connected to power or ground.
            #
            if {[llength $res] != 0} {
                continue
            }

            ##
            # Filter dummy instances.
            #
            set name [$db oid oname $inst]
            set skipDummy false
            foreach dummy {
                "*DUM*"
            } {
                if {[string match $dummy $name]} {
                    set skipDummy true
                    break
                }
            }
            if {$skipDummy} {
                continue
            }

            ##
            # Found a result, add it to the result list.
            #
            zmessage print DBG "      Found result: $gatePin"
            lappend resList $gatePin
        }
        if {[zprogress isinterrupted]} {
            break
        }
    }
    if {[zprogress pop]} {
        return {}
    }

    ##
    # Return the calculated result.
    #
    return $resList
}