cust41/connectPG.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
###############################################################################
# Copyright (c) 2023-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Connect Pin to a PG Net
#   @namespace
#       ConnectPG
#   @section
#       Miscellaneous Userware Examples
#   @description
#       Extend the Popup menu and add a new entry to disconnect the connected
#       net and connect a constant 1 or 0 to the pin.
#       It is also possible to restore the original connectivity.
#   @files
#       cust41/connectPG.tcl
#   @example
#       demo/verilog/gl85.v
#   @cmdline
#       -verilog @example[0]
#       -userware @files[0]
#   @tag
#       gui zdb
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc ConnectPG:Init {} {
    global ConnectPG

    ##
    # Extend the Popup menu.
    #
    gui popup append -menuname "Connect to" "Power (1)"    {ConnectPG:Connect 1}
    gui popup append -menuname "Connect to" "Ground (0)"   {ConnectPG:Connect 0}
    gui popup append -menuname "Connect to" "Original Net" {ConnectPG:Connect N}

    set ConnectPG(filterValue) [gui settings get extract:filterLogicalInvalid]
    gui settings set extract:filterLogicalInvalid 1
}


# =============================================================================
# Finit - Finalize the plugin.
#         This procedure is automatically called when deactivating the plugin.
# =============================================================================
#
proc ConnectPG:Finit {} {
    global ConnectPG

    ##
    # Undo modifications of the GUI.
    #
    gui popup remove -menuname "Connect to" "Power (1)"
    gui popup remove -menuname "Connect to" "Ground (0)"
    gui popup remove -menuname "Connect to" "Original Net"

    gui settings set extract:filterLogicalInvalid $ConnectPG(filterValue)
    array unset ConnectPG
}


# =============================================================================
# Connect - Manipulate the connectivity.
# =============================================================================
#
proc ConnectPG:Connect {value oidList} {
    set db [gui database get]
    if {$db == {}} {
        return
    }

    switch -- $value {
        "0" {
            set netName  "__constant__value__ground__"
            set setValue [list -value 0]
        }
        "1" {
            set netName  "__constant__value__power__"
            set setValue [list -value 1]
        }
        "N" {
            set netName  ""
            set setValue {}
        }
        default {
            error "Wrong value '$value' (0, 1 or N expected)."
        }
    }
    set pinList {}
    foreach oid $oidList {
        set type [$db oid type $oid]
        if {$type eq "pin"} {
            lappend pinList $oid
        } elseif {$type eq "pinBus"} {
            $db foreach pin $oid {
                lappend pinList $pin
            }
        }
    }
    foreach pin $pinList {
        if {[$db isConnected $pin]} {
            set net [$db connectedNet $pin]
            $db oper disconnect $pin
            if {[$db attr $pin getValue "!ORIG_NET_NAME"] eq ""} {
                $db attr $pin set "!ORIG_NET_NAME=[$db oid oname $net]"
            }
        }
        if {$netName eq ""} {
            set netName [$db attr $pin getValue "!ORIG_NET_NAME"]
        }
        if {$netName eq ""} {
            continue
        }
        $db reloadModule [$db oid oname [$db parentModule $pin]]
        $db load net $netName \
            -pin [$db oid oname $pin] [$db oid pname $pin] \
            {*}$setValue
    }
    gui database modified
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
ConnectPG:Init