1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307 | ###############################################################################
# Copyright (c) 2020-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform. As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose. Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
# @userware
# Report All Instance Parameters
# @section
# Create Reports
# @description
# Example Tcl script that uses ZDB API commands to extract all
# instance parameters (default and non-default) and print a report to an
# output file.
# The script may get confused by "(* ... *)"-style Verilog attributes and
# parameters with the same name as internal Vision attributes.
#
# Usage:
# starsh reportAllInstanceParameters.tcl design.zdb report.txt
# @files
# cust33/reportAllInstanceParameters.tcl
# @tag
# zdb batch report rtl
###############################################################################
namespace eval ReportAllInstanceParameters {
}
# =============================================================================
# Main - Report parameterized instances with their default and non-default
# parameters.
# =============================================================================
#
proc ReportAllInstanceParameters::Main {argc argv} {
##
# Check for 2 command line options
#
if {$argc != 2} {
set msg "Wrong number of args. Usage:\n"
append msg "[info nameofexecutable] [info script]"
append msg " <BINFILE> <REPORTFILE>"
error $msg
}
##
# The design is given as the first argument on the command line.
#
set binfile [lindex $argv 0]
##
# The report file is the second argument on the command line.
#
set report [lindex $argv 1]
##
# Open the binfile.
#
set db [zdb open $binfile]
##
# Open the report file.
#
set channel [open $report "w"]
##
# Create instance parameters report.
#
createReport $db $channel
##
# Close the report file.
#
close $channel
##
# Close the opened database.
#
$db close
}
# -----------------------------------------------------------------------------
# createReport - Traverse the db and dump the parameters report into $channel.
# -----------------------------------------------------------------------------
#
proc ReportAllInstanceParameters::createReport {db channel} {
##
# Collect all cell parameters.
# Mark all parameterized cells with $flag.
# Clear flags first.
#
set flag "red"
$db flag -db clear $flag
set cellParameters [dict create]
$db foreach cell cell {
set parameters [getAllParameters $db $cell]
if {[dict size $parameters] > 0} {
##
# Mark the cell with $flag.
#
$db flag $cell set $flag
##
# Collect parameters.
#
dict set cellParameters [$db oid oname $cell] $parameters
}
}
##
# No parameterized cells found.
#
if {[dict size $cellParameters] == 0} {
puts $channel "No parameterized modules found in the design."
return
}
##
# Get the top design.
#
set top [$db get_top_design]
##
# Find all instances of marked cells.
#
$db flat foreach instOfCell $flag $top instance {
##
# Print the instance's path.
#
puts $channel [$db oid print $instance -notype]
##
# Determine the instantiated cell.
#
set cell [$db oid down $instance]
set cellName [$db oid oname $cell]
##
# Print the original cell name.
#
set rtlName [$db attr $cell getValue "RTL_Name"]
if {$rtlName != {}} {
puts $channel "\tcell: $rtlName"
} else {
puts $channel "\tcell: $cellName"
}
##
# Parse the cell name (which contains non-default parameters!).
#
set ok 1
set nonDefaultParameters [getNameParameters $cellName ok]
if {!$ok} {
puts $channel "\tWARNING: Syntax errors when parsing parameters\
from cell name $cellName"
puts $channel "\tWARNING: -> reported parameters may be wrong"
}
##
# Print parameters.
#
set allParameters [dict get $cellParameters $cellName]
dict for {key value} $allParameters {
if {![dict exists $nonDefaultParameters $key]} {
puts $channel "\t$key = $value (default)"
} else {
puts $channel "\t$key = $value"
}
}
##
# Print parameters only found at the instance, but not at the cell.
#
dict for {key value} $nonDefaultParameters {
if {![dict exists $allParameters $key]} {
puts $channel "\t$key = $value (instance-only parameter)"
}
}
}
}
# -----------------------------------------------------------------------------
# getAllParameters - Get attributes from $oid and extract parameters.
# -----------------------------------------------------------------------------
#
proc ReportAllInstanceParameters::getAllParameters {db oid} {
set parameters [dict create]
$db attr $oid foreach attribute {
lassign [splitKeyValue $attribute] key value
switch -glob -- $key {
"!*" -
"@*" -
"BLOCKING" -
"ORIGINAL_PRIMITIVE_FUNCTION" -
"PROCESS_ID" -
"RAM_RANGE" -
"RTL_Name" -
"SHARED_VARIABLE" -
"clock" -
"strength0" -
"strength1" {
##
# internal, non-parameter attribute => skip
#
}
default {
dict set parameters $key $value
}
}
}
return $parameters
}
# -----------------------------------------------------------------------------
# splitKeyValue - Split key=value into {key value}.
# -----------------------------------------------------------------------------
#
proc ReportAllInstanceParameters::splitKeyValue {attribute} {
set attribute [string trim $attribute]
set position [string first "=" $attribute]
if {$position < 0} {
return [list $attribute ""]
}
if {$position == 0} {
return [list "" [string range $attribute 1 end]]
}
set key [string range $attribute 0 [expr {$position - 1}]]
set value [string range $attribute [expr {$position + 1}] end]
return [list $key $value]
}
# -----------------------------------------------------------------------------
# getNameParameters - Parse parameters from $name.
# -----------------------------------------------------------------------------
#
proc ReportAllInstanceParameters::getNameParameters {name okRef} {
upvar 1 $okRef ok
set ok 1
set parameters [dict create]
if {![regexp {^([^\(\)]*)\((.*)\)([^\(\)])*$} $name -> prefix s suffix]} {
return $parameters
}
set parameter ""
set parens 0
foreach c [split $s ""] {
switch -exact -- $c {
"(" {
incr parens
append parameter $c
}
")" {
incr parens -1
append parameter $c
if {$parens < 0} {
set ok 0
}
}
"," {
if {$parens == 0} {
dict set parameters {*}[splitKeyValue $parameter]
set parameter ""
} else {
append parameter $c
}
}
default {
append parameter $c
}
}
}
if {$parameter ne ""} {
dict set parameters {*}[splitKeyValue $parameter]
}
if {$parens != 0} {
set ok 0
}
return $parameters
}
##
# Run the script with the provided command-line parameters.
#
ReportAllInstanceParameters::Main $argc $argv
|