setNetValue.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
###############################################################################
# Copyright (c) 2017-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Set Net Value
#   @namespace
#       SetNetValue
#   @section
#       Modify the Loaded Database
#   @description
#       Extend the Popup menu with functions to set value of selected nets to
#       `0`/`1`/`X`/`Z` or flag them as `power`/`negpower`/`ground`.
#   @files
#       setNetValue.tcl
#   @example
#       demo/spice/gl85.sp
#   @cmdline
#       -hspice @example[0]
#       -userware @files[0]
#   @tag
#       gui zdb rtl verilog spice
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc SetNetValue:Init {} {
    set menu "Set Net Value"
    gui popup append -menuname $menu "0"      "SetNetValue:_value 0"
    gui popup append -menuname $menu "1"      "SetNetValue:_value 1"
    gui popup append -menuname $menu "X"      "SetNetValue:_value X"
    gui popup append -menuname $menu "Z"      "SetNetValue:_value Z"

    gui popup append -menuname $menu "PWR"    "SetNetValue:_flag power"
    gui popup append -menuname $menu "NEGPWR" "SetNetValue:_flag negpower"
    gui popup append -menuname $menu "GND"    "SetNetValue:_flag ground"
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc SetNetValue:Finit {} {
    set menu "Set Net Value"
    gui popup remove -menuname $menu "0"
    gui popup remove -menuname $menu "1"
    gui popup remove -menuname $menu "X"
    gui popup remove -menuname $menu "Z"

    gui popup remove -menuname $menu "PWR"
    gui popup remove -menuname $menu "NEGPWR"
    gui popup remove -menuname $menu "GND"
}


# -----------------------------------------------------------------------------
# _value - Set the value of selected nets/netBuses.
# -----------------------------------------------------------------------------
#
proc SetNetValue:_value {value oidList} {
    ##
    # Return if no database loaded or if the oidList is empty.
    #
    set db [gui database get]
    if {($db == "") || ([llength $oidList] == 0)} {
        return
    }

    set doneSomething 0
    foreach oid $oidList {
        ##
        # Set the value of net/netBus objects.
        #
        if {[string match "net*" [$db oid type $oid]]} {
            $db value $oid $value
            set doneSomething 1
        }
    }

    if {$doneSomething} {
        ##
        # Info the GUI about the modified DB.
        #
        gui database modified
    }
}


# -----------------------------------------------------------------------------
# _flag - Set the given flag on selected nets/netBuses.
# -----------------------------------------------------------------------------
#
proc SetNetValue:_flag {flag oidList} {
    ##
    # Return if no database loaded or if the oidList is empty.
    #
    set db [gui database get]
    if {($db == "") || ([llength $oidList] == 0)} {
        return
    }

    set doneSomething 0
    foreach oid $oidList {
        set type [$db oid type $oid]
        if {$type == "net"} {
            ##
            # Set the flag of net objects.
            #
            $db flag $oid set $flag
            set doneSomething 1
        } elseif {$type == "netBus"} {
            ##
            # Set the flag of netBus members.
            #
            $db foreach net $oid netoid {
                $db flag $netoid set $flag
            }
            set doneSomething 1
        }
    }

    if {$doneSomething} {
        ##
        # Info the GUI about the modified DB.
        #
        gui database modified
    }
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
SetNetValue:Init