libertyArea.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
###############################################################################
# Copyright (c) 2017-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Liberty Area
#   @namespace
#       LibertyArea
#   @section
#       Analyze the Loaded Database
#   @description
#       Add a new main menu entry to calculate the estimated chip area based
#       on the Liberty area attribute.
#   @files
#       libertyArea.tcl
#   @tag
#       rtl verilog
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc LibertyArea:Init {} {
    global LibertyArea

    ##
    # Add menu entries.
    #
    gui menu command {"Userware" "Liberty Area"} [list LibertyArea:Run]

    set LibertyArea(callbackRegistered) 0
    if {![gui plugin check]} {
        set LibertyArea(callbackRegistered) \
            [gui database runOrRegisterChangedCallback LibertyArea:Run]
    }
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc LibertyArea:Finit {} {
    global LibertyArea

    ##
    # Undo modifications of the GUI.
    #
    gui menu removeEntry {"Userware" "Liberty Area"}

    if {![gui plugin check]} {
        if {$LibertyArea(callbackRegistered)} {
            gui database removeChangedCallback LibertyArea:Run
            set LibertyArea(callbackRegistered) 0
        }
    }
}


# =============================================================================
# Run - for each module, compute the sum of the 'area' attributes of all
#       instances inside the module.
# =============================================================================
#
proc LibertyArea:Run {{db {}}} {
    ##
    # Return if the database is empty.
    #
    if {$db == {}} {
        set db [gui database get]
        if {$db == {}} {
            return
        }
    }

    ##
    # Initialize a hash table to store all cells with no area attribute.
    #
    array set _noAreaAtCell {}

    ##
    # Make sure that the database cells are topologically sorted.
    #
    $db oper tsort

    ##
    # Loop over all modules in the loaded design and calculate the total area.
    #
    $db foreach module module {
        ##
        # Initialize the total area for this module.
        #
        set totalArea 0

        ##
        # Loop over all instances of this module.
        #
        $db foreach inst $module inst {
            ##
            # Get the cell referenced by the instance.
            #
            set cell [$db down $inst]

            ##
            # Get the value of the area attribute at the cell.
            #
            set area [$db attr $cell getValue "area"]

            ##
            # Skip instances with no area attribute at the cell.
            #
            if {$area == ""} {
                set _noAreaAtCell([$db oid oname $cell]) 1
                continue
            }

            ##
            # Increase the total area size.
            #
            set totalArea [expr {$totalArea + $area}]
        }

        ##
        # Add an area attribute at the module with the total calculated area.
        #
        $db attr $module set "area=$totalArea"
    }

    ##
    # Show messages for all cells without an area attribute.
    #
    foreach cellName [array names _noAreaAtCell] {
        gui console print "No 'area' attribute at cell '$cellName'"
    }

    ##
    # Loop over all tops in the loaded design and get the total area value.
    #
    $db foreach top top {
        gui console print \
            "Area@[$db oid oname $top] = [$db attr $top getValue "area"]"
    }
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
LibertyArea:Init