cust38/excludeCell.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
###############################################################################
# Copyright (c) 2021-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @userware
#       Exclude Cells from the Cone Extraction
#   @section
#       Miscellaneous Userware Examples
#   @description
#       Read the side file 'excludeCell.txt' and match the name patterns
#       against the loaded database to flag cells exclude from the cone
#       extraction.
#   @files
#       cust38/excludeCell.tcl
#   @tag
#       zdb
###############################################################################


# -----------------------------------------------------------------------------
# _start - Registered database changed callback.
# -----------------------------------------------------------------------------
#
proc ExcludeCell:_start {configFile db} {
    ##
    # Return if the database is empty.
    #
    if {$db != {}} {
        ExcludeCell:_enable $configFile
    }
}


# -----------------------------------------------------------------------------
# _disable - Remove the exclude flag from all database cells.
# -----------------------------------------------------------------------------
#
proc ExcludeCell:_disable {} {
    ##
    # Get the database and return if the database is empty.
    #
    set db [gui database get]
    if {$db == {}} {
        return
    }

    ##
    # Remove the exclude flag from all database cells.
    #
    $db foreach cell cell {
        $db flag $cell clear exclude
    }
}


# -----------------------------------------------------------------------------
# _enable - Read the side file and flag the database cells.
# -----------------------------------------------------------------------------
#
proc ExcludeCell:_enable {configFile} {
    ##
    # Get the database and return if the database is empty.
    #
    set db [gui database get]
    if {$db == {}} {
        return
    }

    set excludeCellPatternList {}
    set in [open $configFile rb]
    while {![eof $in]} {
        set line [string trim [gets $in]]
        if {($line eq "") || [string match "#*" $line]} {
            continue
        }
        lappend excludeCellPatternList $line
    }
    close $in

    $db foreach cell cell {
        $db flag $cell clear exclude
        set cellName [$db oid oname $cell]
        foreach excludeCellPattern $excludeCellPatternList {
            if {[string match $excludeCellPattern $cellName]} {
                $db flag $cell set exclude
            }
        }
    }
}


##
# Set the path to the configuration file containing the exclude cell patterns.
#
set configFile [file join [file dirname [info script]] "excludeCell.txt"]

##
# Add menu entries to enable or disable the excluded cells.
#
gui menu command {"Userware" "Enable Exclude Cells"} \
    [list ExcludeCell:_enable $configFile]
gui menu command {"Userware" "Disable Exclude Cells"} \
    [list ExcludeCell:_disable]

##
# Register ExcludeCell:_start to be run on database changes,
# and immediately if there already is a database.
#
gui database runAndRegisterChangedCallback [list ExcludeCell:_start $configFile]