1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311 | ###############################################################################
# Copyright (c) 2015-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform. As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose. Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
# @plugin
# Display Comments
# @namespace
# DisplayComment
# @section
# Miscellaneous Userware Examples
# @description
# Add comments from a file to the netlist.
# @files
# cust34/displayComment.tcl
# @example
# demo/api/cust34/commentCircuit.sp
# demo/api/cust34/comment.nv
# @cmdline
# -spice @example[0]
# -userware2 @files[0] @example[1]
# @tag
# zdb gui
###############################################################################
# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc DisplayComment:Init {argc argv} {
global DisplayComment
##
# Display net comments only at the wire, not at the connected pin.
#
gui settings set "nlv:netattrwire" 1
gui settings set "nlv:netattrpin" 0
gui settings set "nlv:showattribute" 1
gui settings changed
##
# Add a new menu entry to access the procedure of this script.
#
gui menu command {Userware {Load Comment File}} \
"DisplayComment:_commentDialog"
##
# If this script was loaded using -userware2 then the given argument
# specifies the name of the comment file. In this case register the
# 'DisplayComment:_databaseChanged' procedure to be executed as soon as the
# database is available (netlist read).
#
if {$argc == 1} {
gui database registerChangedCallback \
[list DisplayComment:_databaseChanged [lindex $argv 0]]
set DisplayComment(callbackRegistered) true
}
}
# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc DisplayComment:Finit {} {
global DisplayComment
gui menu removeEntry {Userware {Load Comment File}}
if {[info exists DisplayComment(callbackRegistered)]} {
gui database removeChangedCallback "DisplayComment:_databaseChanged"
array unset DisplayComment
}
}
# -----------------------------------------------------------------------------
# _databaseChanged - Callback for changed database.
# -----------------------------------------------------------------------------
#
proc DisplayComment:_databaseChanged {fname db} {
##
# Check if a database is available (netlist is loaded).
#
if {$db == {}} {
return
}
DisplayComment:_readCommentFile $fname $db
}
# -----------------------------------------------------------------------------
# _commentDialog - Open the dialog to allow the user to select a comment file.
# -----------------------------------------------------------------------------
#
proc DisplayComment:_commentDialog {} {
##
# First check if a database is available (netlist is loaded).
#
set db [gui database get]
if {$db == {}} {
zmessage print ERR "Cannot read comment file: No database loaded."
return
}
##
# Show an open file dialog to browse for an input file.
#
set ftype {{"Comment File" ".nv"}}
set fname [gui window fileDialog openFile "Open a Comment File" $ftype]
##
# Return from this procedure if the file name is empty.
#
if {$fname eq ""} {
return
}
DisplayComment:_readCommentFile $fname $db
}
# -----------------------------------------------------------------------------
# _readCommentFile - Read the comment file and store all found net names and
# corresponding values in a hash table.
# -----------------------------------------------------------------------------
#
proc DisplayComment:_readCommentFile {fname db} {
##
# Open the comment file for reading.
#
set in [open $fname rb]
##
# Initialize used variables.
#
array set _cmap {}
##
# Read the comment file line by line.
#
while {![eof $in]} {
##
# Get the next line.
#
set line [string trim [gets $in]]
if {$line == ""} {
continue
}
set first [string first "*" $line]
if {$first == 0} {
continue
}
##
# Extract the node name and the value.
#
set name [lindex $line 0]
set value [lindex $line 1]
##
# Store the name and the value.
#
set _cmap($name) $value
}
##
# Close the input file.
#
close $in
##
# Call 'DisplayComment:_displayComment' to add display attributes.
#
DisplayComment:_displayComment $db _cmap
}
# -----------------------------------------------------------------------------
# _displayComment - Add attributes to the database containing the comment
# value for all nodes entered into the hash table given
# by its name.
# -----------------------------------------------------------------------------
#
proc DisplayComment:_displayComment {db cmapName} {
##
# Access net name and comment value array one level above.
#
upvar 1 $cmapName _cmap
##
# First search for all global flagged nodes.
#
array set _globalNodes {}
##
# Loop over all database modules (sub-circuits).
#
$db foreach module module {
##
# Inside each module loop over all nets.
#
$db foreach net $module net {
##
# Check if the net is flagged as a global net.
#
if {![$db flag $net is global]} {
continue
}
##
# Get the net name.
#
set netName [$db oid oname $net]
##
# Check if this net is entered in the _cmap table.
#
if {[info exists _cmap($netName)]} {
##
# Add the '@comment' attribute to the global node.
#
$db attr $net set "@comment=$_cmap($netName)"
##
# Remember all global nets.
#
set _globalNodes($netName) 1
}
}
}
##
# Remove already processed global nets from the _cmap table.
#
foreach netName [array names _globalNodes] {
array unset _cmap $netName
}
##
# Use the first top level module.
#
set top [$db get_top_design]
if {$top == {}} {
error "No top level found."
}
##
# Loop over all remaining nets in _cmap.
#
foreach {name value} [array get _cmap] {
##
# Get the OID of the net.
#
if {[catch {
set net [$db oid createFromString net $top $name "." -icase]
} errMsg]} {
zmessage print ERR $errMsg
continue
}
##
# Show an error if the net could not be found.
#
if {[$db oid isnull $net]} {
zmessage print ERR "Net '$name' could not be found."
continue
}
##
# Add the flat '@comment' attribute to the signal and net.
#
set signal [$db oid convertTo signal $net]
$db flatattr $signal set "@comment=$value"
$db flat foreach net $signal n {
$db flatattr $n set "@comment=$value"
}
}
##
# Make the '@comment' attribute visible.
#
$db attr -db set @nlv:net=%{@comment}
$db attr -db set @nlv:powernet=%{@comment}
##
# Inform the GUI about changed attributes.
#
gui attribute changed
}
# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
DisplayComment:Init $argc $argv
|