zeroDriverCheck.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
###############################################################################
# Copyright (c) 2006-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Check for Zero Drivers
#   @namespace
#       ZeroDriverCheck
#   @section
#       Analyze the Loaded Database
#   @description
#       Loop over all signals and check if a signal has no driver.
#   @files
#       zeroDriverCheck.tcl
#   @example
#       demo/rtl/wb_sys/conmax_top.f
#   @cmdline
#       -pedantic off
#       -F @example[0]
#       -userware @files[0]
#   @tag
#       gui zdb rtl netlist
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc ZeroDriverCheck:Init {} {
    gui database runOrRegisterChangedCallback ZeroDriverCheck:Run
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc ZeroDriverCheck:Finit {} {
    gui database removeChangedCallback ZeroDriverCheck:Run
}


# =============================================================================
# Run - loop over all signals and check if a signal has no driver.
# =============================================================================
#
proc ZeroDriverCheck:Run {db} {
    ##
    # If database changed to null-string.
    #
    if {$db == ""} {
        return
    }

    set resList {}              ;# result List

    set top [$db get_top_design]

    $db flat foreach signal $top sig {
        ##
        # skip power, ground and negpower nets
        #
        if {[$db isPgNet $sig]} {
            continue
        }

        ##
        # Skip nets with a value
        #
        set skip 0
        $db flat foreach net $sig net {
            if {[$db value $net] != ""} {
                set skip 1
                break
            }
        }
        if {$skip} {
            continue
        }

        set noDriver 1
        $db flat foreach pin $sig pin {
            set dir [$db directionOf $pin]
            if {[$db oid type $pin] == "port"} {
                if {$dir == "input" || $dir == "inout"} {
                    set noDriver 0
                    break
                }
            } else {
                if {$dir == "output" || $dir == "inout"} {
                    set noDriver 0
                    break
                }
            }
        }
        if {$noDriver} {lappend resList $sig}
    }

    ##
    # Clear and activate the Mem Window
    #
    gui mem clear
    gui window show Mem
    gui window show Schem

    ##
    # Store the result into the Mem Window.
    #
    gui mem append $resList
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
ZeroDriverCheck:Init