toggleBitblasted.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
###############################################################################
# Copyright (c) 2010-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Toggle Bitblasted
#   @namespace
#       ToggleBitblasted
#   @section
#       Modify the Loaded Database
#   @description
#       Extend the Popup menu with a `Toggle Bitblasted` entry that allows for
#       exchanging buses in the selected instances by bitblasted nets, and
#       vice versa.
#   @files
#       toggleBitblasted.tcl
#   @example
#       demo/rtl/aquarius/aquarius.f
#   @cmdline
#       -F @example[0]
#       -userware @files[0]
#   @tag
#       gui rtl verilog
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc ToggleBitblasted:Init {} {
    gui popup append "Toggle Bitblasted" "ToggleBitblasted:Run"
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc ToggleBitblasted:Finit {} {
    gui popup remove "Toggle Bitblasted"
}


# =============================================================================
# Run - iterate over oidList and toggle the instances from bused to bitblasted
#       and vice versa.
# =============================================================================
#
proc ToggleBitblasted:Run {oidList} {
    ##
    # Get the database.
    #
    set db [gui database get]
    if {$db == {}} {
        return
    }

    ##
    # Loop over all given objects and process only instances.
    #
    set newCellName ""
    foreach oid $oidList {
        if {[$db oid type $oid] != "inst"} {
            continue
        }

        ##
        # Get the name of the new cell.
        #
        set newCellName [ToggleBitblasted:_toggleCellOfInst $db $oid]

        ##
        # Change the referenced cell of this instance.
        #
        $db oper changecellref $oid $newCellName

        ##
        # Set the invisible flag at the "old" cell.
        #
        $db flag [$db down $oid] set invisible

        ##
        # Clear the invisible flag at the "new" cell.
        #
        $db flag [$db search cell $newCellName] clear invisible
    }

    ##
    # Only call "update" if something was done in the above loop.
    #
    if {$newCellName ne ""} {
        ##
        # Update all existing OIDs.
        #
        $db oper changecellref -updateOIDs

        ##
        # Inform the GUI that the database has been modified.
        #
        gui database modified
    }
}


# -----------------------------------------------------------------------------
# _toggleCellOfInst - toggle the cell referenced by the given instance
#                     between a bitblasted or a bused version. Create the
#                     bitblasted  version if necessary.
# -----------------------------------------------------------------------------
#
proc ToggleBitblasted:_toggleCellOfInst {db inst} {
    ##
    # Specify the suffix for blasted cells.
    #
    set suffix "__@bitblasted"

    ##
    # If this instance already refers to a bitblasted cell then return
    # the original name (remove the suffix from the cell name).
    #
    set cellName [$db oid cname $inst]
    if {[string match "*$suffix" $cellName]} {
        return [string range $cellName 0 end-[string length $suffix]]
    }

    ##
    # Append the suffix to the cell name. If such a cell already exists
    # then simply return the blasted cell name.
    #
    append cellName $suffix
    if {![$db oid isnull [$db search cell $cellName]]} {
        return $cellName
    }

    ##
    # Create a bitblasted clone of this cell.
    #
    $db clone -bitblasted [$db down $inst] $cellName

    ##
    # Return the name of the new bitblasted cell.
    #
    return $cellName
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
ToggleBitblasted:Init