skill/skillServer.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
#!/usr/bin/env tclsh
###############################################################################
# Copyright (c) 2020-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @userware
#       Socket Server for Virtuoso
#   @section
#       Miscellaneous Userware Examples
#   @description
#       Socket Server started from skillServer.il
#
#       This file should be installed in the same directory as
#       skillServer.il and needs *execute permission*
#
#       It needs path access to a working tclsh interpreter.
#   @files
#       skill/skillServer.tcl
#   @tag
#       skill
###############################################################################


##
# The port number must match with skillClient.tcl
#
if {[info exists env(SKILLSERVPORT)]} {
    set port $env(SKILLSERVPORT)
} else {
    set port 8123
}


# -----------------------------------------------------------------------------
# listener - reroute socket input to sendToSkill
# -----------------------------------------------------------------------------
#
proc listener {channel addr port} {
    puts "$channel CeSkillServerConnection(\"$addr\" \"$port\")"
    flush stdout
    chan configure $channel -buffering line
    set callback [list sendToSkill $channel]
    chan event $channel readable $callback
}


# -----------------------------------------------------------------------------
# sendToSkill - output socket input to stdout, which is read by skill IPC.
# -----------------------------------------------------------------------------
#
proc sendToSkill {channel} {
    if {[eof $channel] || [catch {gets $channel line}]} {
        ##
        # end of file
        #
        close $channel
    } else {
        puts "$channel $line"
        flush stdout
    }
}


# -----------------------------------------------------------------------------
# sendBack - process stdin input and reroute it $channel (first word in line)
# -----------------------------------------------------------------------------
#
proc sendBack {} {
    gets stdin line

    regsub {^(\w+) .*$} $line {\1} channel
    regsub {^\w+ (.*)$} $line {\1} result

    if {![catch {eof $channel}]} {
        puts $channel $result
    }
}


# -----------------------------------------------------------------------------
# send input on $port to listener
# send input on stdin to sendBack
# -----------------------------------------------------------------------------
#
chan configure stdin -buffering line
set callback sendBack
chan event stdin readable $callback

socket -server listener $port
vwait forever