manipulateDesign/replace.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
###############################################################################
# Copyright (c) 2021-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @script
#       Replace devices by fake instances.
###############################################################################


# =============================================================================
# ReplaceDevices -
# =============================================================================
#
proc ::ManipulateDesign::ReplaceDevices {} {
    variable _ReplaceMap

    set db [gui database get]
    if {$db == {}} {
        return
    }

    RecordReplace

    zprogress begin

    ##
    # Render the netlist, such that we can get the device orientations.
    #
    gui database modified

    set _ReplaceMap [dict create]
    set nlv [gui cone nlv]

    $db foreach module module_oid {
        ##
        # Store Nlview orientations in ZDB.
        #
        $db foreach inst $module_oid inst_oid {
            if {[$db tdevice $inst_oid] && \
                [gui nlview isDisplayed $nlv $inst_oid] \
            } {
                $db orient $inst_oid [gui nlview getOrientation $nlv $inst_oid]
                RecordRotate $inst_oid [$db orient $inst_oid]
            }
        }

        $db foreach inst $module_oid inst_oid {
            if {![$db tdevice $inst_oid]} {
                continue
            }

            zprogress update "REPLACING $inst_oid" 0 1

            _replaceDevice $db $inst_oid
        }
    }

    zprogress end

    gui database modified
}


# =============================================================================
# ReplaceReset -
# =============================================================================
#
proc ::ManipulateDesign::ReplaceReset {} {
    variable _ReplaceMap

    set _ReplaceMap {}
}


# -----------------------------------------------------------------------------
# _replaceDevice -
# -----------------------------------------------------------------------------
#
proc ::ManipulateDesign::_replaceDevice {
    db
    inst_oid
} {
    variable _ReplaceMap

    set primitive_oid [$db primitiveOf $inst_oid]
    set name [$db oid oname $primitive_oid]
    if {![dict exists $_ReplaceMap $name]} {
        set new_name [$db uniqueName "" cell non_device_${name}]
        dict set _ReplaceMap $name $new_name
        set new_primitive \
            [_clonePrimitive $db $inst_oid $primitive_oid $new_name]
    } else {
        set new_name [dict get $_ReplaceMap $name]
        set new_primitive [$db search cell $new_name]
    }

    $db oper changecellref $inst_oid $new_name
}


# -----------------------------------------------------------------------------
# _clonePrimitive -
# -----------------------------------------------------------------------------
#
proc ::ManipulateDesign::_clonePrimitive {
    db
    inst_oid
    primitive_oid
    new_name
} {
    $db clone -setfunc UNKNOWN $primitive_oid $new_name
    set clone_oid [$db search cell $new_name]
    $db attr $clone_oid set ORIGINAL_FUNC=[$db primFuncOf $inst_oid]

    set symbol [gui nlview getSymbol $inst_oid]
    $db attr $clone_oid set @symbol=$symbol

    ##
    # Copy port negation flags from the symbol string to ZDB.
    #
    set len [llength $symbol]
    for {set i 0} {$i < $len} {incr i} {
        if {[lindex $symbol $i] eq "pin"} {
            incr i
            set name [lindex $symbol $i]
            incr i
            if {[string match *.neg [lindex $symbol $i]]} {
                set port_oid [$db search port $clone_oid $name]
                if {[$db oid isnull $port_oid]} {
                    zmessage print WAR \
                        "Replace Device: cannot find port '$name' in cloned\
                         primitive '$clone_oid'"
                } else {
                    $db flag $port_oid set neg
                }
            }
        }
    }

    return $clone_oid
}