1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285 | ###############################################################################
# Copyright (c) 2011-2025 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform. As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose. Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
# @plugin
# Ignore Devices
# @namespace
# IgnoreDevice
# @section
# Miscellaneous Userware Examples
# @description
# Extend the popup menu with the options to ignore or grey out devices.
# The ignored devices are stored in the Mem window and can be undone.
# @files
# ignoreDevice.tcl
# @example
# demo/spice/asiclib.sp
# @cmdline
# -hspice @example[0]
# -userware @files[0]
# @tag
# zdb gui
###############################################################################
##
# Configure the appearance of the ignored devices.
#
set IgnoreDevice(grey) [gui settings get "color:objectgrey"]
# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc IgnoreDevice:Init {} {
##
# Enable the appearance attributes in the Nlview windows.
#
gui settings set "nlv:appearanceAttrs" 1
gui settings set "nlv:flatAppearanceAttrs" 1
##
# Customize the Popup Menu.
#
gui popup command \
{"Userware" "Ignore Device" "Currently Selected Device"} \
[list IgnoreDevice:Start "ignore_device"]
gui popup command \
{"Userware" "Ignore Device" "Search for Other Devices"} \
[list IgnoreDevice:Start "dialog_ignore"]
gui popup command \
{"Userware" "Undo Ignore"} \
[list IgnoreDevice:Start "undo_ignore"]
gui popup command \
{"Userware" "Grey out Device" "Currently Selected Device"} \
[list IgnoreDevice:Start "grey_device"]
gui popup command \
{"Userware" "Grey out Device" "Search for Other Devices"} \
[list IgnoreDevice:Start "dialog_grey"]
gui popup command \
{"Userware" "Undo Grey out"} \
[list IgnoreDevice:Start "undo_grey"]
}
# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc IgnoreDevice:Finit {} {
gui popup remove "Userware"
}
# =============================================================================
# Start - Highlight reduced objects marked with a $CONSISTINGOF attribute.
# =============================================================================
#
proc IgnoreDevice:Start {command oidList} {
##
# Return if the database is empty.
#
set db [gui database get]
if {$db == {}} {
return
}
IgnoreDevice:_$command $db $oidList
}
# -----------------------------------------------------------------------------
# _ignore_device - Ignore the selected devices.
# -----------------------------------------------------------------------------
#
proc IgnoreDevice:_ignore_device {db oidList} {
set ignoreList {}
foreach device $oidList {
if {[$db oid type $device] eq "inst"} {
$db flag $device set ignore
lappend ignoreList $device
}
}
if {$ignoreList != {}} {
gui mem append $ignoreList
gui database modified
}
}
# -----------------------------------------------------------------------------
# _undo_ignore - Undo the ignore of the selected devices.
# -----------------------------------------------------------------------------
#
proc IgnoreDevice:_undo_ignore {db oidList} {
foreach device $oidList {
if {[$db oid type $device] eq "inst"} {
$db flag $device clear ignore
}
}
gui database modified
}
# -----------------------------------------------------------------------------
# _grey_device - Grey out the selected devices.
# -----------------------------------------------------------------------------
#
proc IgnoreDevice:_grey_device {db oidList} {
global IgnoreDevice
foreach device $oidList {
if {[$db oid type $device] eq "inst"} {
$db flatattr $device set "@color=$IgnoreDevice(grey)"
}
}
if {$oidList != {}} {
gui database modified
}
}
# -----------------------------------------------------------------------------
# _undo_grey - Undo grey out of the selected devices.
# -----------------------------------------------------------------------------
#
proc IgnoreDevice:_undo_grey {db oidList} {
foreach device $oidList {
if {[$db oid type $device] eq "inst"} {
$db flatattr $device delete "@color"
}
}
gui database modified
}
# -----------------------------------------------------------------------------
# _dialog_ignore - Ignore devices based on an interactive search.
# -----------------------------------------------------------------------------
#
proc IgnoreDevice:_dialog_ignore {db oidList} {
IgnoreDevice:_dialog $db "ignore_device"
}
# -----------------------------------------------------------------------------
# _dialog_grey - Grey out devices based on an interactive search.
# -----------------------------------------------------------------------------
#
proc IgnoreDevice:_dialog_grey {db oidList} {
IgnoreDevice:_dialog $db "grey_device"
}
# -----------------------------------------------------------------------------
# _dialog - Show a dialog to search for other devices.
# -----------------------------------------------------------------------------
#
proc IgnoreDevice:_dialog {db command} {
if {$command eq "ignore_device"} {
set what "Ignore"
} else {
set what "Grey Out"
}
set t [toplevel .ignoreDeviceDialog]
ttk::entry $t.pattern
ttk::button $t.search \
-text "Search" \
-command [list IgnoreDevice:_search $t $db]
ttk::frame $t.f
set _Table $t.f.table
tablelist::tablelist $t.f.table \
-columns { \
0 "Model" left \
0 "Instances" right \
} \
-selectmode extended \
-stretch all
gui window autoscroll $t.f $t.f.table
ttk::frame $t.b
ttk::button $t.b.cancel -text "Cancel"
ttk::button $t.b.action -text "$what Devices"
pack $t.b.cancel $t.b.action -side left -padx 7 -pady 3 -fill x -expand 1
grid $t.pattern -row 0 -column 0 -sticky we
grid $t.search -row 0 -column 1 -sticky e
grid $t.f -row 1 -column 0 -columnspan 2 -sticky news
grid $t.b -row 2 -column 0 -columnspan 2 -sticky we
grid columnconfigure $t 0 -weight 1
grid rowconfigure $t 1 -weight 1
set res [gui window dialog $t "Search for Devices to $what" \
-buttons [list $t.b.cancel $t.b.action]]
if {$res > 0} {
$db foreach top top {
IgnoreDevice:_action $t $db $top $command
}
}
destroy $t
}
# -----------------------------------------------------------------------------
# _search - Search for models matching the pattern.
# -----------------------------------------------------------------------------
#
proc IgnoreDevice:_search {w db} {
set modelList {}
set pattern [$w.pattern get]
$w.f.table delete 0 end
$db foreach cell cell {
set model [$db oid oname $cell]
if {[string match -nocase $pattern $model]} {
$w.f.table insert end [list $model [$db refCount $cell]]
}
}
$w.f.table selection set 0 end
}
# -----------------------------------------------------------------------------
# _action - Perform the action command on the all instances of the
# selected model names.
# -----------------------------------------------------------------------------
#
proc IgnoreDevice:_action {w db top command} {
$db foreach cell cell {
$db flag $cell clear red
}
foreach {name count} [$w.f.table get [$w.f.table curselection]] {
set cell [$db search cell $name]
$db flag $cell set red
}
set deviceList {}
$db flat foreach instOfCell red $top inst {
lappend deviceList $inst
}
IgnoreDevice:_$command $db $deviceList
}
# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
IgnoreDevice:Init
|