expandConnectivity.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
###############################################################################
# Copyright (c) 2012-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Expand Connectivity
#   @namespace
#       ExpandConnectivity
#   @section
#       Analyze the Loaded Database
#   @description
#       Expand the connectivity of devices in the Cone window excluding all
#       the MOS devices that are connected to the net by the 'gate' pin.
#   @license
#       permit spice
#   @files
#       expandConnectivity.tcl
#   @example
#       demo/spice/gl85.sp
#   @cmdline
#       -hspice @example[0]
#       -userware @files[0]
#   @tag
#       spice gui
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc ExpandConnectivity:Init {} {
    ##
    # Register a new custom popup entry.
    #
    gui popup append "Expand Connectivity" [list ExpandConnectivity:Start]
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc ExpandConnectivity:Finit {} {
    ##
    # Clear the custom popup entry.
    #
    gui popup remove "Expand Connectivity"
}


# =============================================================================
# Start - Loop over all given net objects and find connections to gate pins
#         of MOS transistors. These connections are excluded from the result.
# =============================================================================
#
proc ExpandConnectivity:Start {oidList} {
    ##
    # Return if the database is empty.
    #
    set db [gui database get]
    if {$db == {}} {
        return
    }

    ##
    # Initialize the result list.
    #
    set expandList {}

    ##
    # Loop over all given OIDs.
    #
    foreach oid $oidList {
        ##
        # Check if this OID is a pin.
        #
        if {[$db oid type $oid] == "pin"} {
            ##
            # Check if the pin is connected to a net.
            #
            if {[$db isConnected $oid]} {
                ##
                # Make sure that this pin is also part of the result.
                #
                lappend expandList $oid

                ##
                # Set the oid variable to the connected net.
                #
                set oid [$db connectedNet $oid]
            }
        }

        ##
        # Skip all OIDs that are not referring to a net OID type.
        #
        if {[$db oid type $oid] != "net"} {
            continue
        }

        ##
        # Now loop over all connections of this net.
        #
        $db foreach pin $oid pin {
            ##
            # Skip hidden pins.
            #
            if {[$db flag $pin is hide]} {
                continue
            }

            ##
            # A connection to a port is part of the result.
            #
            if {[$db oid type $pin] == "port"} {
                lappend expandList $pin
                continue
            }

            ##
            # Now the net can only be connected to an instance pin.
            # Convert the pin to an instance OID.
            #
            set inst [$db oid convertTo inst $pin]

            ##
            # Check if this instance is a MOS device.
            #
            if {[string match "*MOS" [$db primFuncOf $inst]]} {
                ##
                # Get the name of the connected pin and skip all gate pins.
                #
                if {[$db oid pname $pin] == "g"} {
                    continue
                }
            }

            ##
            # Append this pin to the result list.
            #
            lappend expandList $pin
        }
    }

    ##
    # Append the result to the Cone window.
    #
    gui cone append $expandList
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
ExpandConnectivity:Init