1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198 | ###############################################################################
# Copyright (c) 2015-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform. As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose. Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
# @script
# Stacked NFETs and Diode String
#
# Algorithm
# 1. Identify all toplevel I/O ports connected to NFETs.
# 2. Check that NFETs are stacked and count them.
# 3. Verify one down diode and count the number of up diodes.
# 4. Check that the number of stacked NFETs is at least equal to the
# the number of "up" diodes plus 1.
# 5. Add the violating nets to the result list.
#
# Example
# demo/api/esd/testcase06.sp
###############################################################################
# -----------------------------------------------------------------------------
# check06Port - Check whether for top level ports.
# -----------------------------------------------------------------------------
#
proc ESD:check06Port {db port resultListVar} {
upvar 1 $resultListVar resultList
##
# get connected net
#
set net [ESD:connectedNet $db $port]
if {$net == {}} {
return
}
##
# Ignore non power nets
#
if {[ESD:isPG $db $net]} {
return
}
##
# loop over all connected pins
#
set nfetCnt 0
set diodeUpCnt 0
set diodeDownCnt 0
set oids {}
$db flat foreach pin -addHier $net pin {
##
# Ignore start port
#
if {[$db oid isequal $pin $port]} {
continue
}
##
# store hierPins
#
if {[$db oid type $pin] == "port"} {
lappend oids $pin
continue
}
##
# Get pin function of inst
#
set pinFunc [ESD:funcName $db $pin]
##
# Check all allowed types
#
switch -- $pinFunc {
"anode" {
set diodeUpCnt [ESD:series $db $pin $pinFunc power oids]
}
"cathode" {
set diodeDownCnt [ESD:series $db $pin $pinFunc ground oids]
}
"source" -
"drain" {
set primFunc [$db primFuncOf $pin]
if {$primFunc eq "NMOS"} {
set nfetCnt [ESD:series $db $pin $pinFunc ground oids]
}
}
default {
##
# all other pins (and hierpins) which might be connected
#
lappend oids $pin
}
}
}
##
# Ignore ports with no nfets
#
if {$nfetCnt == 0} {
return
}
##
# Check for invalid nfet configurations
#
if {$nfetCnt == 1} {
##
# not stacked nfet
#
ESD:appendResult resultList $port $oids "only one nfet"
return
}
##
# Check for more up diodes than nfet stack count.
#
if {$diodeUpCnt > $nfetCnt} {
ESD:appendResult resultList $port $oids "more up diodes than nfets"
return
}
##
# Check for an equal number of up diodes and nfet stack count.
#
if {$diodeUpCnt == $nfetCnt} {
set msg "equal number of up diodes and nfets"
ESD:appendResult resultList $port $oids $msg
return
}
##
# Check for enough down diodes
#
if {$diodeDownCnt == 0} {
ESD:appendResult resultList $port $oids "no down diode"
return
}
##
# OK
#
ESD:appendResult resultList $port $oids ""
}
# =============================================================================
# Check06 - Stacked NFETs and Diode String.
# =============================================================================
#
proc ESD:Check06 {db} {
##
# Initialize the result list.
#
set resultList {}
##
# Get top module.
#
set top [$db get_top_design]
##
# Loop over all top level ports
#
set count 0
$db foreach port $top port {
incr count
}
##
# Loop over all top level ports
#
set i 0
$db foreach port $top port {
zprogress push "" [expr {double([incr i]) / $count}]
ESD:check06Port $db $port resultList
if {[zprogress pop]} {
break
}
}
##
# Return the calculated result.
#
return $resultList
}
|