erc/utils.tcl

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
###############################################################################
# Copyright (c) 2012-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @script
#       Utils for ERC
###############################################################################


# =============================================================================
# FlagDevices - Utility procedure to flag devices using red and green.
# =============================================================================
#
proc ERC:FlagDevices {db greenList} {
    ##
    # Clear the red and green flag at all cells.
    #
    set count [$db count cell]
    set i 0
    zprogress push "" 0.4
    $db foreach cell cell {
        if {[zprogress update "" [incr i] $count]} {
            break
        }

        $db flag $cell clear red
        $db flag $cell clear green
    }
    if {[zprogress pop]} {
        return
    }

    ##
    # Loop over all primitives in the loaded database.
    #
    set count [$db count primitive]
    set i 0
    zprogress push "" 1.0
    $db foreach primitive primitive {
        if {[zprogress update "" [incr i] $count]} {
            break
        }

        ##
        # Get the function of this primitive.
        #
        set func [$db primFuncOf $primitive]

        ##
        # If the function is in the given list of 'green' devices then set the
        # green flag at this device to identify them in the cone search.
        #
        if {[lsearch -exact $greenList $func] >= 0} {
            $db flag $primitive set green
        }

        ##
        # All other devices (except devices with the function 'RES') will
        # be flagged with the red flag to exclude them from the cone search.
        #
        if {$func ne "RES"} {
            $db flag $primitive set red
        }
    }
    zprogress pop
}


# =============================================================================
# IsConnectedToPG - Utility procedure to check if the given pin is connected
#                   to a power or ground net (identified by the given flag).
# =============================================================================
#
proc ERC:IsConnectedToPG {db pin flag} {
    set     cmd [list $db coneToPG $pin]
    lappend cmd -excludeFlaggedCell red
    if {$flag != {}} {
        lappend cmd -only $flag
    }
    set res [eval $cmd]

    if {[llength $res] > 0} {
        return true
    }

    return false
}