1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314 | ###############################################################################
# Copyright (c) 2020-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform. As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose. Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
# @userware
# DB Diff (Batch Mode Version)
# @section
# Miscellaneous Userware Examples
# @description
# Compare two ZDBs. Differences are printed to STDOUT. If there are no
# differences, the script terminates with exit code 0, otherwise with
# exit code 1.
#
# Usage:
# ```
# starsh diff_nogui.tcl [OPTIONS...] <ZDB_FILE1> <ZDB_FILE2>
# --ignore-case
# Ignore case when comparing names.
# --ignore-equivalent-primitives
# Consider primitives with the same function to be equivalent.
# --normalize-arrays
# Normalize array/bus names.
# --skip-cells
# Don't report cells that only exist in one DB.
# --skip-connectivity
# Don't report connectivity differences (nets, netbuses, ...).
# --skip-instances
# Don't report instances that only exist in one DB.
# --skip-interfaces
# Don't report interface differences (e.g. ports, portbuses).
# ```
# @files
# Diff/diff_nogui.tcl
# Diff/diff_common.tcl
# @tag
# zdb
###############################################################################
namespace eval DiffNoGui {
variable _ZDB1
variable _ZDB2
variable _Differences
variable _Skip
}
# =============================================================================
# Main - The main function.
# =============================================================================
#
proc DiffNoGui::Main {
argv
} {
variable _ZDB1
variable _ZDB2
variable _Differences
variable _Skip
set zdb1_file ""
set zdb2_file ""
set ignore_case 0
set ignore_equivalent_primitives 0
set normalize_arrays 0
set _Skip [dict create CELLS 0 CONNECTIVITY 0 INSTANCES 0 INTERFACES 0]
foreach arg $argv {
switch -- $arg {
--ignore-case {
set ignore_case 1
}
--ignore-equivalent-primitives {
set ignore_equivalent_primitives 1
}
--normalize-arrays {
set normalize_arrays 1
}
--skip-cells {
dict set _Skip CELLS 1
}
--skip-connectivity {
dict set _Skip CONNECTIVITY 1
}
--skip-instances {
dict set _Skip INSTANCES 1
}
--skip-interfaces {
dict set _Skip INTERFACES 1
}
-* {
_usage
}
default {
if {$zdb1_file eq ""} {
set zdb1_file $arg
} elseif {$zdb2_file eq ""} {
set zdb2_file $arg
} else {
_usage
}
}
}
}
if {($zdb1_file eq "") || ($zdb2_file eq "")} {
_usage
}
if {![file exists $zdb1_file]} {
puts stderr "ERROR: file does not exist: $zdb1_file"
_usage
}
if {![file exists $zdb2_file]} {
puts stderr "ERROR: file does not exist: $zdb2_file"
_usage
}
if {[catch {
set _ZDB1 [zdb open $zdb1_file]
} msg]} {
puts stderr "ERROR: while loading ZDB $zdb1_file\n$msg"
_usage
}
if {[catch {
set _ZDB2 [zdb open $zdb2_file]
} msg]} {
puts stderr "ERROR: while loading ZDB $zdb2_file\n$msg"
_usage
}
set _Differences 0
source [file join [file dirname [info script]] diff_common.tcl]
DiffCommon::Compute \
$_ZDB1 $_ZDB2 \
DiffNoGui::_report DiffNoGui::_report_list \
$ignore_case \
$ignore_equivalent_primitives \
$normalize_arrays
$_ZDB1 close
$_ZDB2 close
if {$_Differences > 0} {
puts "TOTAL DIFFERENCES: $_Differences"
exit 1
}
exit 0
}
# -----------------------------------------------------------------------------
# _usage - Display usage message and exit.
# -----------------------------------------------------------------------------
#
proc DiffNoGui::_usage {} {
puts -nonewline stderr "USAGE: [info nameofexecutable] [info script] "
puts stderr "\[OPTIONS...\] <ZDB_FILE1> <ZDB_FILE2>"
puts stderr " --ignore-case"
puts stderr " Ignore case when comparing names."
puts stderr " --ignore-equivalent-primitives"
puts stderr " Consider primitives with the same function to be\
equivalent."
puts stderr " --normalize-arrays"
puts stderr " Normalize array/bus names."
puts stderr " --skip-cells"
puts stderr " Don't report cells that only exist in one DB."
puts stderr " --skip-connectivity"
puts stderr " Don't report connectivity differences\
(nets, netbuses, ...)."
puts stderr " --skip-instances"
puts stderr " Don't report instances that only exist in one DB."
puts stderr " --skip-interfaces"
puts stderr " Don't report interface differences\
(e.g. ports, portbuses)."
exit 1
}
# -----------------------------------------------------------------------------
# _report - Display single object report.
# -----------------------------------------------------------------------------
#
proc DiffNoGui::_report {
class
path sub
val1 val2
obj1 obj2
{parent1 {}} {parent2 {}}
} {
variable _Differences
if {[_skip $class]} {
return
}
incr _Differences
set p1 [lindex $path end-1]
if {$p1 == {}} {
puts "GLOBAL: $sub (CLASS: $class)"
} else {
puts "IN {$p1}: $sub (CLASS: $class)"
}
if {($val1 eq "missing") && \
($val2 eq "") && \
($obj1 == {}) && \
($obj2 != {}) \
} {
puts " {$obj2} IS MISSING IN ZDB1"
} elseif {($val2 eq "missing") && \
($val1 eq "") && \
($obj1 != {}) && \
($obj2 == {}) \
} {
puts " {$obj1} IS MISSING IN ZDB2"
} elseif {$obj1 eq $obj2} {
puts " ZDB1 VALUE=$val1"
puts " ZDB2 VALUE=$val2"
} else {
puts " ZDB1 VALUE=$val1 OBJECT={$obj1}"
puts " ZDB2 VALUE=$val2 OBJECT={$obj2}"
}
}
# -----------------------------------------------------------------------------
# _report_list - Display object list report.
# -----------------------------------------------------------------------------
#
proc DiffNoGui::_report_list {
class
path sub
list1 list2
obj1 obj2
pairwise
} {
variable _Differences
if {[_skip $class]} {
return
}
incr _Differences
set p1 [lindex $path end-1]
if {$p1 == {}} {
puts "GLOBAL: $sub (CLASS: $class)"
} else {
puts "IN {$p1}: $sub (CLASS: $class)"
}
if {$pairwise} {
foreach it1 $list1 it2 $list2 {
if {$it1 eq ""} {
puts " {$it2} IS MISSING IN ZDB1"
} elseif {$it2 eq ""} {
puts " {$it1} IS MISSING IN ZDB2"
} elseif {$it1 eq $it2} {
##
# nothing
#
} else {
puts " ZDB1 VALUE=$it1"
puts " ZDB2 VALUE=$it2"
}
}
} else {
foreach it $list1 {
puts " {$it} IS MISSING IN ZDB2"
}
foreach it $list2 {
puts " {$it} IS MISSING IN ZDB1"
}
}
}
# -----------------------------------------------------------------------------
# _skip - Return true if the report class should be skipped.
# -----------------------------------------------------------------------------
#
proc DiffNoGui::_skip {
class
} {
variable _Skip
if {![dict exists $_Skip $class]} {
puts "INVALID REPORT CLASS: $class"
return 0
}
return [dict get $_Skip $class]
}
# =============================================================================
# Call the main procedure.
# =============================================================================
#
DiffNoGui::Main $argv
|