showFunc.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
###############################################################################
# Copyright (c) 2012-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Show Function
#   @namespace
#       ShowFunc
#   @section
#       Miscellaneous Userware Examples
#   @description
#       Add a main menu entry to toggle the display of the function at each
#       primitive instance.
#   @files
#       showFunc.tcl
#   @example
#       demo/rtl/aquarius/aquarius.f
#   @cmdline
#       -F @example[0]
#       -userware @files[0]
#   @tag
#       gui
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc ShowFunc:Init {} {
    global ShowFunc

    ##
    # Add menu entry for toggling.
    #
    set ShowFunc(displayFunc) 0
    gui menu checkbutton {"Userware" "Display Function"} \
        [list ShowFunc:_toggleFunc] \
        ShowFunc(displayFunc)

    ##
    # Register ShowFunc:_addFunc to be run on database changes,
    # and immediately if there's already is a database.
    #
    gui database runAndRegisterChangedCallback [list ShowFunc:_addFunc]
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc ShowFunc:Finit {} {
    ##
    # Undo modifications of the GUI.
    #
    gui menu removeEntry {"Userware" "Display Function"}

    ##
    # Remove the callback registration.
    #
    gui database removeChangedCallback "ShowFunc:_addFunc"
}


# -----------------------------------------------------------------------------
# _addFunc - This procedure adds the func value to all primitive instances.
# -----------------------------------------------------------------------------
#
proc ShowFunc:_addFunc {db} {
    global ShowFunc

    ##
    # Return if the database is empty.
    #
    if {$db == {}} {
        return
    }

    ##
    # Add func attribute to all primitive instances.
    #
    $db foreach module module {
        $db foreach inst $module inst {
            if {[$db isModule $inst]} {
                continue
            }
            $db attr $inst add func=[$db primFuncOf $inst]
        }
    }

    if {$ShowFunc(displayFunc)} {
        ShowFunc:_toggleFunc
    }
}


# -----------------------------------------------------------------------------
# _toggleFunc - Append or removes the FUNC= display string from all primitives.
# -----------------------------------------------------------------------------
#
proc ShowFunc:_toggleFunc {} {
    global ShowFunc

    ##
    # Return if the database is empty.
    #
    set db [gui database get]
    if {$db == {}} {
        return
    }

    ##
    # Change @nlv meta attribute on all primitives.
    #
    set dspFunc "\nFUNC=%{func}"
    $db foreach primitive prim {
        ##
        # Get the current value of the @nlv attribute.
        #
        set curAttrValue [$db attr $prim getValue "@nlv"]
        set attr         [$db attr $prim getValue "@nlv"]

        ##
        # Toggle the FUNC display attribute.
        #
        if {$ShowFunc(displayFunc)} {
            set newAttrValue $curAttrValue
            if {![string match "*FUNC=*" $curAttrValue]} {
                append newAttrValue $dspFunc
            }
        } else {
            set newAttrValue [string map [list $dspFunc ""] $curAttrValue]
        }
        $db attr $prim set "@nlv=$newAttrValue"
    }
    gui attribute changed
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
ShowFunc:Init