1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331 | ###############################################################################
# Copyright (c) 2020-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform. As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose. Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
# @plugin
# Replace Devices
# @namespace
# ReplaceDevices
# @section
# Modify the Loaded Database
# @description
# Extend the Popup menu to replace selected device-type instances by
# non-device instances to allow for rotation, moving, etc.
# @files
# replaceDevices.tcl
# @tag
# zdb
###############################################################################
namespace eval ReplaceDevices {
variable _Primitives [dict create]
variable _Prefix NON_DEVICE_
variable _PopupName \
"Replace Selected Device Instances by Non-Device Variants"
variable _MenuPathAll \
{"Userware" "Replace *All* Device Instances by Non-Device Variants"}
variable _MenuPathCurrent \
{"Userware" "Replace Device Instances by Non-Device Variants in the\
Current Module"}
}
# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc ::ReplaceDevices::Init {} {
variable _PopupName
variable _MenuPathAll
variable _MenuPathCurrent
gui database registerChangedCallback ::ReplaceDevices::_onDatabaseChanged
gui popup append $_PopupName ::ReplaceDevices::_replaceSelected
gui menu command $_MenuPathAll ::ReplaceDevices::_replaceAll
gui menu command $_MenuPathCurrent ::ReplaceDevices::_replaceInCurrentModule
}
# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc ::ReplaceDevices::Finit {} {
variable _PopupName
variable _MenuPathAll
variable _MenuPathCurrent
gui database removeChangedCallback ::ReplaceDevices::_onDatabaseChanged
gui popup remove $_PopupName
gui menu removeEntry $_MenuPathAll
gui menu removeEntry $_MenuPathCurrent
}
# -----------------------------------------------------------------------------
# _onDatabaseChanged -
# -----------------------------------------------------------------------------
#
proc ::ReplaceDevices::_onDatabaseChanged {db} {
variable _Primitives
set _Primitives [dict create]
}
# -----------------------------------------------------------------------------
# _replaceSelected -
# -----------------------------------------------------------------------------
#
proc ::ReplaceDevices::_replaceSelected {oids} {
set db [gui database get]
if {$db == {}} {
return
}
##
# Store orientations from the transistor layout engine in ZDB
# before performing any replacements.
#
set nlv [gui schem nlv]
foreach oid $oids {
if {[_isReplaceable $db $oid] && [gui nlview isDisplayed $nlv $oid]} {
$db orient $oid [gui nlview getOrientation $nlv $oid]
}
}
set needs_reload 0
foreach oid $oids {
if {![_isReplaceable $db $oid]} {
continue
}
_replaceDevice $db $oid
set needs_reload 1
}
_finalizeReplace $db $needs_reload
}
# -----------------------------------------------------------------------------
# _replaceAll -
# -----------------------------------------------------------------------------
#
proc ::ReplaceDevices::_replaceAll {} {
set db [gui database get]
if {$db == {}} {
return
}
set needs_reload 0
$db foreach module module_oid {
if {[_replaceInModule $db $module_oid]} {
set needs_reload 1
}
}
_finalizeReplace $db $needs_reload
}
# -----------------------------------------------------------------------------
# _replaceInCurrentModule -
# -----------------------------------------------------------------------------
#
proc ::ReplaceDevices::_replaceInCurrentModule {} {
set db [gui database get]
if {$db == {}} {
return
}
set needs_reload [_replaceInModule $db [gui schem getCurrentModule]]
_finalizeReplace $db $needs_reload
}
# -----------------------------------------------------------------------------
# _replaceInModule -
# -----------------------------------------------------------------------------
#
proc ::ReplaceDevices::_replaceInModule {db module_oid} {
##
# Store orientations from the transistor layout engine in ZDB
# before performing any replacements.
#
set nlv [gui schem nlv]
$db foreach inst $module_oid oid {
if {[_isReplaceable $db $oid] && [gui nlview isDisplayed $nlv $oid]} {
$db orient $oid [gui nlview getOrientation $nlv $oid]
}
}
set needs_reload 0
$db foreach inst $module_oid oid {
if {![_isReplaceable $db $oid]} {
continue
}
_replaceDevice $db $oid
set needs_reload 1
}
return $needs_reload
}
# -----------------------------------------------------------------------------
# _isReplaceable -
# -----------------------------------------------------------------------------
#
proc ::ReplaceDevices::_isReplaceable {db oid} {
if {[$db oid type $oid] ne "inst"} {
return 0
}
if {![$db tdevice $oid]} {
return 0
}
return 1
}
# -----------------------------------------------------------------------------
# _replaceDevice -
# -----------------------------------------------------------------------------
#
proc ::ReplaceDevices::_replaceDevice {db inst_oid} {
variable _Primitives
variable _Prefix
set primitive_oid [$db primitiveOf $inst_oid]
set primitive_name [$db oid oname $primitive_oid]
if {![dict exists $_Primitives $primitive_name]} {
set new_primitive_name \
[$db uniqueName "" cell ${_Prefix}${primitive_name}]
dict set _Primitives $primitive_name $new_primitive_name
set new_primitive \
[_clonePrimitive $db $inst_oid $primitive_oid $new_primitive_name]
} else {
set new_primitive_name [dict get $_Primitives $primitive_name]
set new_primitive [$db search cell $new_primitive_name]
}
$db oper changecellref $inst_oid $new_primitive_name
}
# -----------------------------------------------------------------------------
# _finalizeReplace -
# -----------------------------------------------------------------------------
#
proc ::ReplaceDevices::_finalizeReplace {db needs_reload} {
if {!$needs_reload} {
return
}
$db oid resetAllOIDs
gui database modified
}
# -----------------------------------------------------------------------------
# _clonePrimitive -
# -----------------------------------------------------------------------------
#
proc ::ReplaceDevices::_clonePrimitive {db inst_oid oid new_name} {
set func [$db primFuncOf $oid]
$db clone -setfunc UNKNOWN $oid $new_name
set clone_oid [$db search cell $new_name]
switch -exact -- $func {
"NMOS" -
"PMOS" -
"NMOSM" -
"PMOSM" -
"NPN" -
"PNP" {
set parent_module_oid [$db parentModule $inst_oid]
set parent_module_name [$db oid oname $parent_module_oid]
set cell_name [$db oid oname $oid]
##
# Unhide all pins (esp. hidden bulks), so that we get the full
# symbol. Save their oids to be able to restore the "hide" flags
# after fetching the symbol.
#
set hidden_pin_oids {}
$db foreach pin $inst_oid pin_oid {
if {[$db flag $pin_oid supported hide] && \
[$db flag $pin_oid is hide] \
} {
$db flag $pin_oid clear hide
lappend hidden_pin_oids $pin_oid
}
}
##
# Fetch the symbol from a headless Nlview; choose the "empty" view
# variant (non-hidden bulk pins).
#
set schem [$db schematic]
$schem loadmodule $parent_module_name
set nlv_symbol {}
foreach s [$schem debug search -def symbol $cell_name] {
set view [lindex $s 2]
if {([llength $nlv_symbol] == 0) || ($view == {})} {
set nlv_symbol $s
}
}
$schem free
##
# Restore hidden pins.
#
foreach pin_oid $hidden_pin_oids {
$db flag $pin_oid set hide
}
set pin_index [lsearch $nlv_symbol "pin"]
set symbol [list DEF {*}[lrange $nlv_symbol $pin_index end]]
}
default {
set symbol $func
$db foreach port $clone_oid port_oid {
set port_name [$db oid oname $port_oid]
set port_direction [$db directionOf $port_oid]
append symbol " pin $port_name $port_direction"
}
}
}
$db attr $clone_oid set @symbol=$symbol
return $clone_oid
}
# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
::ReplaceDevices::Init
|