renameObj.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
###############################################################################
# Copyright (c) 2008-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Manually Rename Objects
#   @namespace
#       RenameObj
#   @section
#       Modify the Loaded Database
#   @description
#       Extend the Popup menu with a `Rename` entry that allows for renaming of
#       the selected object.
#
#       Warning: bad names (e.g. empty names, names of an existing objects,
#       names containing hierarchy separators) may result in an invalid data
#       base.
#   @files
#       renameObj.tcl
#   @example
#       demo/rtl/aquarius/aquarius.f
#   @cmdline
#       -F @example[0]
#       -userware @files[0]
#   @tag
#       gui zdb
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc RenameObj:Init {} {
    gui popup append "Rename" "RenameObj:showDialog"
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc RenameObj:Finit {} {
    gui popup remove "Rename"
}


# -----------------------------------------------------------------------------
# showDialog - Show dialog to enter new name.
# -----------------------------------------------------------------------------
#
proc RenameObj:showDialog {oidList} {
    ##
    # Return if the database is empty.
    #
    set db [gui database get]
    if {$db == {}} {
        return
    }

    ##
    # We expect one net object in $oidList
    #
    if {[llength $oidList] != 1} {
        if {[llength $oidList] > 1} {
            zmessage print WAR "Renaming multiple objects is not supported."
        } else {
            zmessage print INF "No object is selected."
        }
        return
    }

    set obj     [lindex $oidList 0]
    set oldName [$db oid oname $obj]
    set type    [$db oid type $obj]

    if {($type == "pin") || ($type == "pinBus")} {
        zmessage print WAR "Renaming of '$type' objects is not supported."
        return
    }

    set w .userware_rename
    toplevel $w

    ttk::frame $w.f
    ttk::label $w.f.label -text "New Name:"
    ttk::entry $w.f.entry
    $w.f.entry insert 0 $oldName
    grid $w.f.label -row 0 -column 0 -sticky news -padx 4 -pady 4
    grid $w.f.entry -row 0 -column 1 -sticky news -padx 4 -pady 4
    grid columnconfigure $w.f 1 -weight 1

    ttk::frame $w.b
    ttk::button $w.b.cancel -text "Cancel"
    ttk::button $w.b.rename -text "Rename"
    pack $w.b.cancel -side left -expand 1 -fill x -padx 5 -pady 2
    pack $w.b.rename -side left -expand 1 -fill x -padx 5 -pady 2

    grid $w.f -row 0 -column 0 -sticky news
    grid $w.b -row 1 -column 0 -sticky news
    grid columnconfigure $w 0 -weight 1
    grid rowconfigure $w 0 -weight 1

    set button [gui window dialog \
        $w \
        "Rename Object" \
        -place "MOUSE" \
        -focus $w.b.cancel \
        -buttons [list $w.b.cancel $w.b.rename] \
    ]

    if {$button == 1} {
        set newName [$w.f.entry get]
        if {($newName != "") && ($newName != $oldName)} {
            set newObj [lreplace $obj end end $newName]
            if {[catch {$db oid create $newObj}]} {
                $db oper rename -updateOIDs $obj $newName
                gui database modified
            } else {
                zmessage print WAR \
                    "An $type object with this name already exists."
            }
        } else {
            zmessage print WAR "No object was renamed."
        }
    }

    destroy $w
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
RenameObj:Init