highlightDevices.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
###############################################################################
# Copyright (c) 2006-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Highlight Devices
#   @namespace
#       HighlightDevices
#   @section
#       Miscellaneous Userware Examples
#   @description
#       Loop over the loaded database and highlight different devices (based on
#       the model name) in a different color.
#   @configuration
#   @license
#       permit spice
#   @non-interactive
#   @files
#       highlightDevices.tcl
#   @example
#       demo/spice/gl85.sp
#   @cmdline
#       -hspice @example[0]
#       -userware @files[0]
#   @tag
#       spice parasitic dspf spf
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc HighlightDevices:Init {} {
    ##
    # Specify primitive functions that should be assigned a color.
    # See doc/api/tprim.html for a complete list of primitive types.
    #
    gui plugin addConfig HighlightDevices deviceFuncList \
        "NMOS, PMOS, CAP, RES" text \
        "Comma-separated list of device types to be highlighted."

    ##
    # Register HighlightDevices:Start to be run on database changes,
    # and immediately if there's already is a database.
    #
    gui database runAndRegisterChangedCallback [list HighlightDevices:Start]
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc HighlightDevices:Finit {} {
    ##
    # Remove the callback registration.
    #
    gui database removeChangedCallback "HighlightDevices:Start"
}


# =============================================================================
# Start - Loop over all instances in all modules and apply a highlight color
#         for each known device.
# =============================================================================
#
proc HighlightDevices:Start {db} {
    global Global

    ##
    # Return if the database is empty.
    #
    if {$db == {}} {
        return
    }

    array set color {}
    set devFuncList [gui plugin getConfigValue HighlightDevices deviceFuncList]
    foreach funcName [split $devFuncList ","] {
        set func [string trim $funcName]
        set color($func) 1
    }

    ##
    # Count the number of instances and measure the time consumption.
    #
    array set _colorMap {}
    set nextColor -1
    set instCnt 0

    ##
    # Loop over all modules and instances inside each module.
    #
    $db foreach module mod {
        $db foreach inst $mod inst {
            ##
            # Skip module instances.
            #
            if {[$db isModule $inst]} {
                continue
            }

            ##
            # Get the primitive function of this instance and
            # continue the loop if no color is defined for this
            # function.
            #
            set function [$db primFuncOf $inst]
            if {![info exists color($function)]} {
                continue
            }
            if {!$color($function)} {
                continue
            }

            ##
            # Set the highlight color defined for the function
            # of this instance.
            #
            set model [$db oid cname $inst]
            if {![info exists _colorMap($model)]} {
                if {$nextColor == $Global(hiColorMax)} {
                    zmessage print ERR "Running out of highlight colors."
                    continue
                }
                set _colorMap($model) [incr nextColor]
            }
            $db hilight $inst set $_colorMap($model)

            ##
            # Increment the instance count.
            #
            incr instCnt
        }
    }

    ##
    # Update the GUI.
    #
    gui highlight changed
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
HighlightDevices:Init