1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314 | ###############################################################################
# Copyright (c) 2015-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform. As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose. Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
# @script
# ESD Protection for Input Gates
#
# Algorithm
# 1. Identify All MOS devices connected to I/O ports.
# 2. Create net paths through resistors and verify that the gate has
# a path to the I/O port.
# 3. Verify that the R between gate and the I/O port is between
# 50-110 Ohm and HBM diodes exist on the port side.
# 4. Check for a CDM up diode and verify its perimeter.
# 5. Check for a CDM down diode/NFET and verify its perimeter/width.
# 6. Add the violating nets to the result list.
#
# Example
# demo/api/esd/testcase10.sp
###############################################################################
# -----------------------------------------------------------------------------
# check10Diode - check for diode connected to ground.
# -----------------------------------------------------------------------------
#
proc ESD:check10Diode {db pin diodeUpPinsVar diodeDownPinsVar} {
upvar 1 $diodeUpPinsVar diodeUpPins
upvar 1 $diodeDownPinsVar diodeDownPins
set oppositePin [ESD:oppositePin $db $pin]
if {$oppositePin == {}} {
return
}
set net [ESD:connectedNet $db $oppositePin]
if {$net == {}} {
return
}
switch -- [ESD:funcName $db $pin] {
"cathode" {
if {[$db flag $net is ground]} {
lappend diodeDownPins $pin $oppositePin
}
}
"anode" {
if {[$db flag $net is power]} {
lappend diodeUpPins $pin $oppositePin
}
}
default {
}
}
}
# -----------------------------------------------------------------------------
# check10CountPins - get pairs of connected instances and opposite pin.
# -----------------------------------------------------------------------------
#
proc ESD:check10CountPins {db port gatePinsVar \
diodeUpPinsVar diodeDownPinsVar resistorPinsVar extraPinsVar} {
upvar 1 $gatePinsVar gatePins
upvar 1 $diodeUpPinsVar diodeUpPins
upvar 1 $diodeDownPinsVar diodeDownPins
upvar 1 $resistorPinsVar resistorPins
upvar 1 $extraPinsVar extraPins
##
# Init results
#
set gatePins {}
set diodeUpPins {}
set diodeDownPins {}
set resistorPins {}
set extraPins {}
##
# get connected net
#
set net [ESD:connectedNet $db $port]
if {$net == {}} {
return
}
##
# loop over all connected pins
#
$db flat foreach pin -addHier $net pin {
##
# Ignore start
#
if {[$db oid isequal $pin $port]} {
continue
}
##
# store hierPorts
#
if {[$db oid type $pin] == "port"} {
lappend extraPins $pin
continue
}
##
# Get instance of pin
#
set inst [$db oid convertTo inst $pin]
##
# store hierPins
#
if {[$db isModule $inst]} {
lappend extraPins $pin
continue
}
##
# Get primitive type
#
set func [$db primFuncOf $inst]
##
# Check different function.
#
switch -- $func {
"NMOS" -
"PMOS" {
##
# Report directly connected gate pin
#
if {[ESD:funcName $db $pin] eq "gate"} {
lappend gatePins $pin
}
}
"DIODE" {
ESD:check10Diode $db $pin diodeUpPins diodeDownPins
}
"RES" {
##
# Get opposite resistor pin
#
set resistorPin [ESD:oppositePin $db $pin]
if {$resistorPin != {}} {
lappend resistorPins $resistorPin
lappend extraPins $pin
}
}
default {
}
}
}
}
# -----------------------------------------------------------------------------
# check10Port - Check whether port.
# -----------------------------------------------------------------------------
#
proc ESD:check10Port {db port resultListVar} {
upvar 1 $resultListVar resultList
##
# Get connected gate pins
#
set gatePins1 {}
set diodeUpPins1 {}
set diodeDownPins1 {}
set resistorPins {}
set extraPins {}
ESD:check10CountPins $db $port gatePins1 diodeUpPins1 diodeDownPins1\
resistorPins extraPins
##
# Gate pins directly connected to port are invalid
#
if {[llength $gatePins1] > 0} {
foreach gatePin $gatePins1 {
set oids [ESD:filterOids $db $gatePin $port $extraPins]
set msg "port directly connected to gate '[$db oid print $gatePin]'"
ESD:appendResult resultList $port $oids $msg
}
return
}
##
# Check for invalid gates connected via resistor
#
foreach resistorPin $resistorPins {
set gatePins2 {}
set diodeUpPins2 {}
set diodeDownPins2 {}
set moreResistorPins {}
set moreExtraPins {}
ESD:check10CountPins $db $resistorPin gatePins2 diodeUpPins2\
diodeDownPins2 moreResistorPins moreExtraPins
##
# set oids
#
set oids [concat $gatePins1 $gatePins2 \
$diodeUpPins1 $diodeDownPins1\
$diodeUpPins2 $diodeDownPins2\
$extraPins [list $resistorPin]]
##
# Check resistor value for gate pins connected via resistor.
#
if {[llength $gatePins2] > 0} {
##
# check for up/down diodes.
#
if {[llength $diodeUpPins1] == 0} {
set msg "missing first up diode"
ESD:appendResult resultList $port $oids $msg
return
}
if {[llength $diodeUpPins2] == 0} {
set msg "missing second up diode"
ESD:appendResult resultList $port $oids $msg
return
}
if {[llength $diodeDownPins1] == 0} {
set msg "missing first down diode"
ESD:appendResult resultList $port $oids $msg
return
}
if {[llength $diodeDownPins2] == 0} {
set msg "missing second down diode"
ESD:appendResult resultList $port $oids $msg
return
}
##
# Get instance of pin
#
set inst [$db oid convertTo inst $resistorPin]
##
# Get resistor value
#
set resValue [$db attr $inst getValue "R"]
##
# Gate pins connected via too small resistor is invalid
#
if {$resValue < 100} {
set msg "resistor '[$db oid print $inst]'"
append msg " value '$resValue' too small"
ESD:appendResult resultList $port $oids $msg
return
}
##
# OK
#
ESD:appendResult resultList $port $oids ""
}
}
}
# =============================================================================
# Check10 - ESD Protection for Input Gates.
# =============================================================================
#
proc ESD:Check10 {db} {
##
# Initialize the result list.
#
set resultList {}
##
# Get top module.
#
set top [$db get_top_design]
##
# Count top level ports
#
set count 0
$db foreach port $top port {
incr count
}
##
# Loop over all top level ports
#
$db foreach port $top port {
zprogress push "" [expr {double([incr i]) / $count}]
ESD:check10Port $db $port resultList
if {[zprogress pop]} {
break
}
}
##
# Return the calculated result.
#
return $resultList
}
|