deviceName.tcl

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
###############################################################################
# Copyright (c) 2011-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @userware
#       Additional Information in Device Name
#   @section
#       Modify the Loaded Database
#   @description
#       Update the displayed name of all modules to show additional
#       information.
#   @files
#       deviceName.tcl
#   @tag
#       zdb gui spice
###############################################################################


# =============================================================================
# Configure the additional string that should be displayed next to the
# instance name based on the model name.
#          MODEL   +TEXT
# =============================================================================
#
set _config(nchx) "voltage_domain=1.32"
set _config(pchx) "voltage_domain=1.32"
set _config(nchy) "nlow"
set _config(pchy) "plow"


# -----------------------------------------------------------------------------
# deviceName - This is the main procedure that loops over all instances in all
#              modules and update the displayed name.
# -----------------------------------------------------------------------------
#
proc deviceName {db} {
    global _config

    ##
    # Loop over all modules.
    #
    $db foreach module module {
        ##
        # Inside each module loop over all instances.
        #
        $db foreach inst $module inst {
            ##
            # Skip this instance if it is not a device.
            #
            if {![$db tdevice $inst]} {
                continue
            }

            ##
            # Get the cell name of this device instance.
            #
            set cname [$db oid cname $inst]

            ##
            # Skip this instance if there is no configuration entry.
            #
            if {![info exists _config($cname)]} {
                continue
            }

            ##
            # Modify the displayed instance name by setting the @name attr.
            #
            set name [$db oid oname $inst]
            set name "$name (+$_config($cname))"
            $db attr $inst set @name=$name
        }
    }

    ##
    # Inform the GUI that the attributes have been changed.
    #
    gui attribute changed
}


##
# Use gui database runOrRegisterChangedCallback to immediately run
# deviceName
# if we have a database, or otherwise register the proc to be executed after
# the database is available.
#
gui database runOrRegisterChangedCallback deviceName