cust41/readPinList.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
###############################################################################
# Copyright (c) 2023-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Read a Pinlist from a File and Display the Path
#   @namespace
#       ReadPinList
#   @section
#       Miscellaneous Userware Examples
#   @description
#       Read a pin list from a side file and load each pin into the Cone
#       window.
#   @files
#       cust41/readPinList.tcl
#   @example
#       demo/verilog/gl85.v
#   @cmdline
#       -verilog @example[0]
#       -userware @files[0]
#   @tag
#       gui zdb
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc ReadPinList:Init {} {
    ##
    # Add menu entry.
    #
    gui menu command {"Userware" "Load Pin List"} \
        [list ReadPinList:LoadFile]
}


# =============================================================================
# Finit - Finalize the plugin.
#         This procedure is automatically called when deactivating the plugin.
# =============================================================================
#
proc ReadPinList:Finit {} {
    ##
    # Undo modifications of the GUI.
    #
    gui menu removeEntry {"Userware" "Load Pin List"}
}


# =============================================================================
# LoadFile - Load the pin list file.
# =============================================================================
#
proc ReadPinList:LoadFile {{fname ""}} {
    set db [gui database get]
    if {$db == {}} {
        return
    }

    if {$fname eq ""} {
        set fname [gui window fileDialog openFile "Open a pin list file" \
        {{"Pin List" {"*.txt"}}}]
    }
    if {$fname eq ""} {
        return
    }

    set top [$db get_top_design]

    ##
    # Open the file for reading in binary mode.
    #
    set f [open $fname r]
    chan configure $f -translation binary
    set pinList {}
    while {![eof $f]} {
        set line [gets $f]
        set line [string trim $line]

        if {[string match "#*" $line]} {
            continue
        }

        set oid [ReadPinList:_getOid $db $top $line]
        if {$oid != {}} {
            lappend pinList $oid
        }
    }
    close $f

    set hierPinList [ReadPinList:_addHierarchicalPins $db $pinList]
    gui cone load $hierPinList
}


# -----------------------------------------------------------------------------
# _addHierarchicalPins - Add missing hierarchical pins to connect the pins in
#                        the given pin list.
# -----------------------------------------------------------------------------
#
proc ReadPinList:_addHierarchicalPins {db pinList} {
    set result {}

    array set _pinTable {}
    foreach pin $pinList {
        set _pinTable($pin) 0
    }

    foreach pin $pinList {
        if {![$db isConnected $pin]} {
            continue
        }
        if {$_pinTable($pin)} {
            continue
        }
        lappend result $pin
        set net [$db connectedNet $pin]
        set signal [$db flat signalOf $net]
        $db flat foreach pin $signal conPin {
            if {[info exists _pinTable($conPin)]} {
                set _pinTable($pin)    1
                set _pinTable($conPin) 1
                set res [$db cone -shortestPath -targetObj $conPin $pin]
                lappend result {*}$res
            }
        }
    }

    return $result
}


# -----------------------------------------------------------------------------
# _getOid - Convert a string into either a port or pin OID.
# -----------------------------------------------------------------------------
#
proc ReadPinList:_getOid {db top name {hiersep .}} {
    set oid {}

    foreach type {port pin} {
        catch {
            set oid [$db oid createFromString $type $top $name $hiersep -icase]
        }
        if {$oid != {}} {
            break
        }
    }

    return $oid
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
ReadPinList:Init