cust40/postProcessBoard.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
###############################################################################
# Copyright (c) 2022-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @script
#       Post process a database and:
#       - replace generic blocks by the corresponding device function
#         depending on the value of the designator attribute,
#       - display the value of the `Value` attribute and
#       - mark nets as power/ground.
###############################################################################


# =============================================================================
# Start - Start post-processing the database.
# =============================================================================
#
proc PostProcessBoard:Start {interactive db} {
    if {$db eq ""} {
        return
    }

    $db foreach module module {
        $db foreach inst $module inst {
            ##
            # Get the value of the designator attribute and set the
            # corresponding device function.
            #
            set designator [$db attr $inst getValue "designator"]
            switch -exact -- $designator {
                "R?" {
                    set function "RES"
                }
                "C?" {
                    set function "CAP"
                }
                "D?" {
                    set function "DIODE"
                }
                default {
                    set function ""
                }
            }

            ##
            # Get the cell referenced by the instance.
            #
            set cell [$db down $inst]

            ##
            # Display the value of the Value attribute.
            #
            $db attr $cell set @nlv=%Value

            if {$function eq ""} {
                switch -glob -- [$db oid oname $inst] {
                    "R*" {
                        set function "RES"
                    }
                    "C*" {
                        set function "CAP"
                    }
                    "D*" {
                        set function "DIODE"
                    }
                    default {
                        set function ""
                    }
                }
            }

            ##
            # Clone the cell referenced by this instance with the correct
            # device function and point the instance to the cloned cell.
            #
            if {$function ne ""} {
                ##
                # Set the leafcell flag at modules.
                #
                if {[$db isModule $cell]} {
                    $db flag $cell set leafcell
                }

                $db attr $cell set @symbol=$function
            }

            ##
            # Show the designator name.
            #
            if {$designator ne ""} {
                $db attr $inst set "@name=[$db oid oname $inst] ($designator)"
            }

            ##
            # Replace the displayed Pin name by the value of the designator
            # attribute.
            #
            $db foreach pin $inst pin {
                set designator [$db attr $pin getValue "designator"]
                if {$designator ne ""} {
                    $db attr $pin set "@name=$designator"
                }
            }
        }

        ##
        # Mark supply nets using the power, ground or negpower flag and
        # do a connect by name using the hide flag.
        #
        $db foreach net $module net {
            switch -glob -- [$db oid oname $net] {
                "*VP*V*" -
                "*VCC*" -
                "*VDD*" {
                    set netType power
                }
                "*GND*" {
                    set netType ground
                }
                "*CLK*" {
                    set netType hide
                }
                default {
                    continue
                }
            }

            $db flag $net set $netType
        }
    }

    ##
    # Update the GUI.
    #
    if {$interactive} {
        gui database removeChangedCallback PostProcessBoard:Start
        gui database changed $db
        gui database registerChangedCallback [list PostProcessBoard:Start true]
    }
}


##
# Register the PostProcessBoard:Start procedure as a database changed callback.
#
if {(![info exists useInBatchMode]) || (!$useInBatchMode)} {
    gui database runAndRegisterChangedCallback \
        [list PostProcessBoard:Start true]
}