cust30/showLibertyTiming.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
###############################################################################
# Copyright (c) 2016-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Cross-Probe To Liberty Sources
#   @namespace
#       ShowLiberty
#   @section
#       Miscellaneous Userware Examples
#   @description
#       Extend the popup menu with an entry `Show Liberty` to cross-probe from
#       the schematic to Liberty source code.
#   @files
#       cust30/showLibertyTiming.tcl
#   @example
#       demo/api/cust4/example.lib
#       demo/api/cust4/example.v
#   @cmdline
#       -liberty @example[0]
#       -verilog @example[1]
#       -userware @files[0]
#   @tag
#       gui
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc ShowLiberty:Init {} {
    gui database runAndRegisterChangedCallback ShowLiberty:_addSpos

    gui popup append "Show Liberty" "ShowLiberty:_crossProbe"
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc ShowLiberty:Finit {} {
    gui database removeChangedCallback ShowLiberty:_addSpos
    gui popup remove "Show Liberty"
}


# -----------------------------------------------------------------------------
# _addSpos - Add all Liberty files to the Spos database.
# -----------------------------------------------------------------------------
#
proc ShowLiberty:_addSpos {db} {
    ##
    # Return if the database is empty.
    #
    if {$db == {}} {
        return
    }

    ##
    # Loop over all files added to the spos database.
    #
    $db spos foreachfile -idx idx m {
        ##
        # For all Liberty files add the line information.
        #
        if {[$db spos filetype -idx $idx] == "Liberty"} {
            $db spos addline -idx $idx all
        }
    }
}


# -----------------------------------------------------------------------------
# _crossProbe - Show liberty sources of the single object in oidList.
# -----------------------------------------------------------------------------
#
proc ShowLiberty:_crossProbe {oidList} {
    ##
    # Get the database.
    #
    set db [gui database get]

    ##
    # Return if the database is empty.
    #
    if {$db == {}} {
        return
    }

    ##
    # Exactly one selected object expected.
    #
    if {[llength $oidList] != 1} {
        zmessage print WAR "ShowLiberty: one selected object expected."
        return
    }

    ##
    # Get the selected object.
    #
    set oid [lindex $oidList 0]

    ##
    # Get the type of the selected object.
    #
    set type [$db oid type $oid]

    ##
    # Only pin, pinBus and instance objects are supported.
    #
    if {($type != "pin") && ($type != "pinBus") && ($type != "inst")} {
        zmessage print ERR "ShowLiberty: pin, pinBus or inst object expected."
        return
    }

    ##
    # Get the 'down' object:
    #   pin    --> port
    #   pinBus --> portBus
    #   inst   --> cell
    #
    set downOid [$db down $oid]

    ##
    # Get the "LIBERTY_FILE" and "LIBERTY_LINE" attributes at the down object.
    #
    set libertyFile [$db attr $downOid getValue "LIBERTY_FILE"]
    set libertyLine [$db attr $downOid getValue "LIBERTY_LINE"]
    if {($libertyFile == "") || ($libertyLine == "")} {
        zmessage print ERR \
            "ShowLiberty: No Liberty file or line information at '$oid'."
        return
    }

    ##
    # Get the file name for the file index.
    #
    set libertyFname [$db spos getfname -idx $libertyFile]

    ##
    # Make sure the Source window is visible.
    #
    gui window show Source

    ##
    # Show the Liberty file at the line for the selected object.
    #
    gui source highlightLine $libertyFname $libertyLine -dontShow -clear
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
ShowLiberty:Init