1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314 | ###############################################################################
# Copyright (c) 2018-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform. As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose. Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
# @script
# Custom Device View
###############################################################################
##
# Configure the ViewDevice script.
#
set ViewDevice(imageSize) "1980x1050"
set ViewDevice(imageType) "png"
set ViewDevice(imagePrefix) "neighborView"
set ViewDevice(outputDir) "/tmp"
set ViewDevice(interactive) false
set ViewDevice(numberOfLevels) 2
set ViewDevice(deviceNames) {}
# =============================================================================
# Start - This is the main procedure, started as a callback as soon as the
# given input netlist is read.
# =============================================================================
#
proc ViewDevice:Start {} {
global ViewDevice
##
# Get the database and return of the database is empty.
#
set db [gui database get]
if {$db == {}} {
return
}
##
# Get the top design.
#
set top [$db get_top_design]
##
# Activate the Cone window for visual feedback.
#
if {!$ViewDevice(interactive)} {
gui window show Cone
update idletasks
}
##
# Process the list of given device names.
#
foreach name $ViewDevice(deviceNames) {
if {$ViewDevice(interactive)} {
##
# Add a main menu command to display the neighbors.
#
set cmd [list ViewDevice:_displayNeighbors $db $top $name]
gui menu command [list "View Device" "Device $name"] $cmd
} else {
##
# Display the neighbors in the Cone Window.
#
ViewDevice:_displayNeighbors $db $top $name
}
}
##
# Quit the GUI if not running interactive.
#
if {!$ViewDevice(interactive)} {
gui quit
}
}
# -----------------------------------------------------------------------------
# _displayNeighbors -
# -----------------------------------------------------------------------------
#
proc ViewDevice:_displayNeighbors {db top name} {
global ViewDevice
##
# Get an instance OID of the given device name.
#
set inst [$db get_inst $name]
##
# Skip non-existing instances.
#
if {[$db oid isnull $inst]} {
zmessage print ERR "Cannot get instance ${name}."
return
}
##
# Clear any existing highlights.
#
$db flathilight $top deleteAll
##
# Initialize the list of pins that will be loaded to the Cone window.
#
set ViewDevice(pinList) {}
##
# Get all neighbors of this instance.
#
ViewDevice:_getNeighbors $db $inst 0
##
# Load the calculated pin list into the Cone window.
#
gui cone load $ViewDevice(pinList)
update
##
# Update the GUI to see the applied highlights.
#
gui highlight changed
##
# Create an image of the Cone window.
#
ViewDevice:_createImage $name \
$ViewDevice(imageType) \
$ViewDevice(imageSize)
}
# -----------------------------------------------------------------------------
# _getNeighbors -
# -----------------------------------------------------------------------------
#
proc ViewDevice:_getNeighbors {db inst level} {
global ViewDevice
##
# Highlight the start instance.
#
$db flathilight $inst set $level
##
# Return if the maximum number of levels has been reached.
#
if {$level >= $ViewDevice(numberOfLevels)} {
return
}
##
# Get the bulk pin of this instance.
#
set bulk [$db getFuncPort $inst -noError -name "bulk"]
##
# Loop over all pins of the given start instance.
#
set instList {}
$db foreach pin $inst pin {
##
# Once the bulk pin is reached break the pin loop.
#
if {($bulk != {}) && [$db oid isequal $bulk $pin]} {
break
}
##
# Skip unconnected and hidden pins.
#
if {(![$db isConnected $pin]) || [$db flag $pin is hide]} {
continue
}
##
# Each instance pin is part of the result list.
#
lappend ViewDevice(pinList) $pin
##
# Get the net connected to this instance pin.
#
set net [$db connectedNet $pin]
##
# Do not follow power/ground nets.
#
if {[$db isPgNet $net]} {
continue
}
##
# Only if this net has not been visited before apply a highlight color.
#
if {[$db flathilight $net get] eq ""} {
$db flathilight $net set $level
}
##
# Loop over all pins of the net connected to this instance pin.
#
$db foreach pin $net connPin {
##
# Add every connected pin to the result list.
#
lappend ViewDevice(pinList) $connPin
##
# Skip connections to top level ports.
#
if {[$db oid type $connPin] eq "port"} {
continue
}
##
# Get the instance object for this pin.
#
set connInst [$db oid convertTo inst $connPin]
##
# Add only not already processed instances to the instance list
# to be processed further.
#
if {[$db flathilight $connInst get] eq ""} {
lappend instList $connInst
}
}
}
##
# Increment the level and process all next instances.
#
incr level
foreach nextInst $instList {
ViewDevice:_getNeighbors $db $nextInst $level
}
}
# -----------------------------------------------------------------------------
# _createImage - Create an image of the Cone window.
# -----------------------------------------------------------------------------
#
proc ViewDevice:_createImage {name type size} {
global ViewDevice
##
# Set the name of the output filename.
#
set fname "$ViewDevice(imagePrefix)_$name"
set fname [zos sanitizeFilename $fname]
set fname [file join $ViewDevice(outputDir) $fname]
##
# Create an image of the Cone window.
#
gui export photo $fname Cone $size $type
}
##
# Loop over all given arguments to overwrite the default configuration and to
# get the list of device names.
#
for {set i 0} {$i < $argc} {incr i} {
set arg [lindex $argv $i]
switch -exact -- $arg {
"-imageSize" -
"-imageType" -
"-imagePrefix" -
"-outputDir" -
"-interactive" -
"-numberOfLevels" {
set ViewDevice([string range $arg 1 end]) [lindex $argv [incr i]]
}
default {
lappend ViewDevice(deviceNames) $arg
}
}
}
##
# Test the number of given args.
#
if {$argc == 0} {
set msg "Wrong # of args.\n"
append msg "Usage: '-userwareargs [info script] \""
append msg "?-imageSize <1980x1050>? "
append msg "?-imageType <png>? "
append msg "?-imagePrefix <neighborView>? "
append msg "?-outputDir </tmp>? "
append msg "?-interactive <true|false>? "
append msg "?-numberOfLevels <2>? "
append msg "<DeviceName0> <DeviceName1> ... <DeviceNameN>\"'"
error $msg
}
##
# Register the Start procedure to be executed after the design is loaded.
#
gui database registerDesignReadyCallback [list ViewDevice:Start]
|