clockTree.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
###############################################################################
# Copyright (c) 2005-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Clock Tree Extraction
#   @namespace
#       ClockTreeExtraction
#   @section
#       Analyze the Loaded Database
#   @description
#       Extract the clock tree structure of the loaded design.
#
#       Usage:
#       - Right click on an input port (e.g. CLK) and invoke
#       - "Userware->Clock Tree" from the context menu.
#       - Now switch to the Cone window to see the result.
#   @non-interactive
#   @files
#       clockTree.tcl
#   @example
#       demo/rtl/aquarius/aquarius.f
#   @cmdline
#       -F @example[0]
#       -userware @files[0]
#   @tag
#       zdb
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc ClockTreeExtraction:Init {} {
    ##
    # Specify the name of the target clock cell to extract the clock tree here.
    # Here the clock tree is extracted to the built-in " DFFRS" cell.
    #
    gui popup append "Clock Tree" "ClockTreeExtraction:Run { DFFRS}"
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc ClockTreeExtraction:Finit {} {
    gui popup remove "Clock Tree"
}


# =============================================================================
# Run - Extract the cone and analyze the result:
#       Display only one targetCell per module and show the number of
#       total target cells as an attribute.
# =============================================================================
#
proc ClockTreeExtraction:Run {targetCell oidList} {
    if {$oidList == {}} {
        return
    }

    set db   [gui database get]
    set cone [$db cone -out -targetCell $targetCell [lindex $oidList 0]]

    set oidList {}
    foreach oid $cone {
        if {[$db oid type $oid] == "pin"} {
            ##
            # Create an inst oid based on the pin oid.
            #
            set inst [lreplace [lrange $oid 0 end-1] 0 0 inst]

            ##
            # Load module instances, but do not investigate.
            #
            if {[$db isModule $inst]} {
                lappend oidList $oid
                continue
            }

            ##
            # Get the primitive type of this instance.
            #
            set cell [$db primitiveOf $inst]

            ##
            # If the name does not match the target cell then
            # load this instance but skip further investigation.
            #
            if {$targetCell != [$db oid oname $cell]} {
                lappend oidList $oid
                continue
            }

            ##
            # Add the "DFF_COUNT" attribute to the primitive.
            #
            $db attr $cell set @nlv=DFF_COUNT=%DFF_COUNT
            set path [$db oid path $oid]

            ##
            # Count the number of target cells per module.
            #
            if {![info exists dffCount($path)]} {
                set dffCount($path) 0
                set _target($path) $inst
                lappend oidList $oid
            }
            incr dffCount($path)
        } else {
            lappend oidList $oid
        }
    }

    ##
    # Add the "DFF_COUNT" attribute to each target instance.
    #
    foreach path [array names _target] {
        $db flatattr $_target($path) add DFF_COUNT=$dffCount($path)
    }

    ##
    # Load the (reduced) result list to the Cone window and inform the
    # GUI that the attributes have changed.
    #
    gui cone load $oidList
    gui attribute changed
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
ClockTreeExtraction:Init