checkDeviceModel.tcl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
###############################################################################
# Copyright (c) 2011-2024 by Altair Engineering, Inc.
# All rights reserved.
#
# Altair Engineering, Inc. makes this software available as part of the Vision
# tool platform.  As long as you are a licensee of the Vision tool platform
# you may make copies of the software and modify it to be used within the
# Vision tool platform, but you must include all of this notice on any copy.
# Redistribution without written permission to any third party, with or
# without modification, is not permitted.
# Altair Engineering, Inc. does not warrant that this software is error free
# or fit for any purpose.  Altair Engineering, Inc. disclaims any liability for
# all claims, expenses, losses, damages and costs any user may incur as a
# result of using, copying or modifying the software.
# =============================================================================
#   @plugin
#       Check Device Model
#   @namespace
#       CheckDeviceModel
#   @section
#       Analyze the Loaded Database
#   @description
#       Find and highlight io devices matching the given model name pattern.
#   @configuration
#   @files
#       checkDeviceModel.tcl
#   @example
#       demo/spice/multivolt.sp
#   @cmdline
#       -hspice @example[0]
#       -userware @files[0]
#   @tag
#       spice
###############################################################################


# =============================================================================
# Init - Initialize the plugin.
# =============================================================================
#
proc CheckDeviceModel:Init {} {
    gui menu command {"Userware" "Check Device Model"} {CheckDeviceModel:Run}

    gui plugin addConfig \
        CheckDeviceModel \
        ioDevice         \
        "?ch_ll"         \
        text             \
        "Name pattern of io device transistors."
}


# =============================================================================
# Finit - Finalize the plugin.
# =============================================================================
#
proc CheckDeviceModel:Finit {} {
    gui menu removeEntry {"Userware" "Check Device Model"}
}


# =============================================================================
# Run - procedure to find signals that connect a low voltage transistor
#       with a high voltage transistor.
# =============================================================================
#
proc CheckDeviceModel:Run {} {
    ##
    # Get the database, return if the database is empty.
    #
    set db [gui database get]

    ##
    # Return if the database is empty.
    #
    if {$db == {}} {
        return
    }

    set ioDevice [gui plugin getConfigValue CheckDeviceModel ioDevice]

    set resList {}
    $db foreach module module {
        $db foreach inst $module inst {
            ##
            # Clear existing highlight.
            #
            $db hilight $inst delete

            ##
            # Skip instances not matching the io device model pattern.
            #
            if {![string match -nocase $ioDevice [$db oid cname $inst]]} {
                continue
            }

            ##
            # Check the connectivity to identify and highlight io devices.
            #
            set drn [$db getFuncPort $inst -noError -name "drain"]
            set src [$db getFuncPort $inst -noError -name "source"]
            if {!([CheckDeviceModel:_isIoDevice $db $drn]  ||
                  [CheckDeviceModel:_isIoDevice $db $src])} \
            {
                lappend resList $inst
                $db hilight $inst set 0
            } else {
                $db hilight $inst set 1
            }
        }
    }

    gui highlight changed

    ##
    # Show the result list in the Mem window.
    #
    gui window show Mem
    gui mem append $resList
}


# -----------------------------------------------------------------------------
# _isIoDevice -
# -----------------------------------------------------------------------------
#
proc CheckDeviceModel:_isIoDevice {db pin} {
    ##
    # Check the pin and its connectivity.
    #
    if {($pin == {}) || (![$db isConnected $pin])} {
        return false
    }

    ##
    # Get the net connected to this pin.
    #
    set net [$db connectedNet $pin]

    ##
    # Do not follow power/ground nets.
    #
    if {[$db isPgNet $net] || ([$db value $net] ne "")} {
        return false
    }

    ##
    # Loop over all pins of the connected net.
    #
    $db foreach pin $net conPin {
        ##
        # Once the bulk pin is reached break the pin loop.
        #
        if {[$db oid type $conPin] eq "port"} {
            return true
        }
    }

    return false
}


# =============================================================================
# Call the initialization procedure.
# =============================================================================
#
CheckDeviceModel:Init