model WorldForce "External force acting at frame_b, defined by 3 input signals and resolved in frame world, frame_b or frame_resolve"
extends Interfaces.PartialOneFrame_b;
Interfaces.Frame_resolve frame_resolve if resolveInFrame == Modelica.Mechanics.MultiBody.Types.ResolveInFrameB.frame_resolve "The input signals are optionally resolved in this frame"
annotation (Placement(transformation(
origin = {0, -100},
extent = {
{-16, -16},
{16, 16}},
rotation = 270)));
Modelica.Blocks.Interfaces.RealInput force[3](each final quantity = "Force", each final unit = "N") "x-, y-, z-coordinates of force resolved in frame defined by resolveInFrame"
annotation (Placement(transformation(extent = {
{-140, -20},
{-100, 20}})));
parameter Boolean animation = true "= true, if animation shall be enabled";
parameter Modelica.Mechanics.MultiBody.Types.ResolveInFrameB resolveInFrame = Modelica.Mechanics.MultiBody.Types.ResolveInFrameB.world "Frame in which input force is resolved (1: world, 2: frame_b, 3: frame_resolve)";
parameter Real N_to_m(unit = "N/m") = world.defaultN_to_m "Force arrow scaling (length = force/N_to_m)"
annotation (Dialog(
group = "if animation = true",
enable = animation));
input SI.Diameter diameter = world.defaultArrowDiameter "Diameter of force arrow"
annotation (Dialog(
group = "if animation = true",
enable = animation));
input Types.Color color = Modelica.Mechanics.MultiBody.Types.Defaults.ForceColor "Color of arrow"
annotation (Dialog(
colorSelector = true,
group = "if animation = true",
enable = animation));
input Types.SpecularCoefficient specularCoefficient = world.defaultSpecularCoefficient "Reflection of ambient light (= 0: light is completely absorbed)"
annotation (Dialog(
group = "if animation = true",
enable = animation));
protected
SI.Position f_in_m[3] = frame_b.f / N_to_m "Force mapped from N to m for animation";
Visualizers.Advanced.Arrow arrow(diameter = diameter, color = color, specularCoefficient = specularCoefficient, R = frame_b.R, r = frame_b.r_0, r_tail = f_in_m, r_head = -f_in_m) if world.enableAnimation and animation;
public
Internal.BasicWorldForce basicWorldForce(resolveInFrame = resolveInFrame) annotation (Placement(transformation(extent = {
{-10, -10},
{10, 10}})));
protected
Interfaces.ZeroPosition zeroPosition if not resolveInFrame == Modelica.Mechanics.MultiBody.Types.ResolveInFrameB.frame_resolve annotation (Placement(transformation(extent = {
{20, -40},
{40, -20}})));
equation
connect(basicWorldForce.force,force) annotation (Line(
points = {
{-12, 0},
{-120, 0}},
color = {0, 0, 127}));
connect(basicWorldForce.frame_b,frame_b) annotation (Line(
points = {
{10, 0},
{100, 0}},
color = {95, 95, 95},
thickness = 0.5));
connect(basicWorldForce.frame_resolve,frame_resolve) annotation (Line(
points = {
{0, -10},
{0, -100}},
color = {95, 95, 95},
pattern = LinePattern.Dot));
connect(zeroPosition.frame_resolve,basicWorldForce.frame_resolve) annotation (Line(
points = {
{20, -30},
{0, -30},
{0, -10}},
color = {95, 95, 95},
pattern = LinePattern.Dot));
annotation (
defaultComponentName = "force",
Icon(
coordinateSystem(
preserveAspectRatio = true,
extent = {
{-100, -100},
{100, 100}}),
graphics = {
Text(
extent = {
{-100, -40},
{100, -70}},
lineColor = {192, 192, 192},
textString = "resolve"),
Polygon(
points = {
{-100, 10},
{50, 10},
{50, 31},
{94, 0},
{50, -31},
{50, -10},
{-100, -10},
{-100, 10}},
fillPattern = FillPattern.Solid),
Text(
extent = {
{-150, 80},
{150, 40}},
textString = "%name",
lineColor = {0, 0, 255}),
Line(
points = {
{0, -10},
{0, -95}},
color = {95, 95, 95},
pattern = LinePattern.Dot)}),
Documentation(info = "<html>\n\n<p>\nThe <strong>3</strong> signals of the <strong>force</strong> connector are interpreted\nas the x-, y- and z-coordinates of a <strong>force</strong> acting at the frame\nconnector to which frame_b of this component is attached.\nVia parameter <strong>resolveInFrame</strong> it is defined, in which frame these\ncoordinates shall be resolved:\n</p>\n\n<table border=1 cellspacing=0 cellpadding=2>\n<tr><th><strong>Types.ResolveInFrameB.</strong></th><th><strong>Meaning</strong></th></tr>\n<tr><td>world</td>\n <td>Resolve input force in world frame (= default)</td></tr>\n\n<tr><td>frame_b</td>\n <td>Resolve input force in frame_b</td></tr>\n\n<tr><td>frame_resolve</td>\n <td>Resolve input force in frame_resolve (frame_resolve must be connected)</td></tr>\n</table>\n\n<p>\nIf resolveInFrame = Types.ResolveInFrameB.frame_resolve, the force coordinates\nare with respect to the frame, that is connected to <strong>frame_resolve</strong>.\n</p>\n\n<p>\nIf force={100,0,0}, and for all parameters the default setting is used,\nthen the interpretation is that a force of 100 N is acting along the positive\nx-axis of frame_b.\n</p>\n\n<p>\nNote, the cut-torque in frame_b (frame_b.t) is always set to zero.\nConceptually, a force and torque acts on the world frame in such a way that\nthe force and torque balance between world.frame_b and frame_b is fulfilled.\nFor efficiency reasons, this reaction torque is, however, not computed.\n</p>\n\n<p>\nThis force component is by default visualized as an arrow\nacting at the connector to which it is connected. The diameter\nand color of the arrow can be defined via\nvariables <strong>diameter</strong> and <strong>color</strong>. The arrow\npoints in the direction defined by the\nforce signal. The length of the arrow is proportional\nto the length of the force vector using parameter\n<strong>N_to_m</strong> as scaling factor. For example, if N_to_m = 100 N/m,\nthen a force of 350 N is displayed as an arrow of length 3.5 m.\n</p>\n<p>\nAn example how to use this model is given in the\nfollowing figure:\n</p>\n\n<p>\n<img src=\"modelica://Modelica/Resources/Images/Mechanics/MultiBody/Forces/WorldForce1.png\">\n</p>\n\n<p>\nThis leads to the following animation\n</p>\n\n<p>\n<img src=\"modelica://Modelica/Resources/Images/Mechanics/MultiBody/Forces/WorldForce2.png\">\n</p>\n\n</html>"));
end WorldForce;